Đánh số cho các cặp số chứng từ và số chứng từ đối ứng (1 người xem)

Excel my love_1 · 17/7/25

MÌnh cần đánh số các cặp phiếu như trong hình minh họa
Ví dụ cặp số chứng từ và phiếu đối ứng như sau: XT0125-1480 và N0125-0390 với N0125-0390 và XT0125-1480 là 1 cặp phiếu số 1
Logic là:
nếu A và B với B và A sẽ là cặp số 1
nếu C và D với D và C sẽ là cặp số 2
nếu E và F với F và E sẽ là cặp số 3
….......
(Xem hình minh họa, mình đã bôi màu các cặp phiếu để các bạn tiện theo dõi)

Duy Tùng 9x · 17/7/25

Bạn thử này xem sao

Mã:

=LET(a,BYROW(A2:B29,LAMBDA(s,CONCAT(SORT(s,,,1)))),XMATCH(a,UNIQUE(a)))

Duy Tùng 9x · 17/7/25

Office thấp kéo thì bạn thử này xem. Đúng với dữ liệu đó, còn nhiều thì chưa rõ nữa

Mã:

E2=IFNA(LOOKUP(1,0/(MMULT(($A$1:B1=A2)+($A$1:B1=B2),{1;1})),$E$1:E1),MAX($E$1:E1)+1)

HieuCD · 17/7/25

Excel my love_1 đã viết:
MÌnh cần đánh số các cặp phiếu như trong hình minh họa
Ví dụ cặp số chứng từ và phiếu đối ứng như sau: XT0125-1480 và N0125-0390 với N0125-0390 và XT0125-1480 là 1 cặp phiếu số 1
Logic là:
nếu A và B với B và A sẽ là cặp số 1
nếu C và D với D và C sẽ là cặp số 2
nếu E và F với F và E sẽ là cặp số 3
….......
(Xem hình minh họa, mình đã bôi màu các cặp phiếu để các bạn tiện theo dõi)

C2 =IFERROR(LOOKUP(2,1/(($A$1:A1=A2)+($A$1:A1=B2))/(($B$1:B1=B2)+($B$1:B1=A2)),$C$1:C1),MAX($C$1:C1)+1)
Copy xuống . . .

Phan Thế Hiệp · 18/7/25

HieuCD đã viết:
C2 =IFERROR(LOOKUP(2,1/(($A$1:A1=A2)+($A$1:A1=B2))/(($B$1:B1=B2)+($B$1:B1=A2)),$C$1:C1),MAX($C$1:C1)+1)
Copy xuống . . .

Lâu lắm mới thấy anh tung "chiêu" mảng.
Còn đang nghĩ trong đầu dùng countifs(), nhìn kỹ thì anh đã quất sẵn rồi.

"Gừng càng già càng cay"

Chúc anh và gia đình vui khỏe.
/-*+/

HieuCD · 18/7/25

Phan Thế Hiệp đã viết:
Lâu lắm mới thấy anh tung "chiêu" mảng.
Còn đang nghĩ trong đầu dùng countifs(), nhìn kỹ thì anh đã quất sẵn rồi.

"Gừng càng già càng cay"

Chúc anh và gia đình vui khỏe.

Khà Khà Khà! Gừng già khô rồi, Thấy dạng đơn giản nhưng hơi lạ nên làm thử góp vui, dạng khó nhường người khác.
Chúc bạn và gia đình an vui.

thanthanhan · 18/7/25

Phan Thế Hiệp đã viết:
Lâu lắm mới thấy anh tung "chiêu" mảng.
Còn đang nghĩ trong đầu dùng countifs(), nhìn kỹ thì anh đã quất sẵn rồi.

"Gừng càng già càng cay"

Chúc anh và gia đình vui khỏe.

Tôi cũng xin góp vui 1 công thức, cách làm không được hay như mọi người ở trên
=IFERROR(IF(A2=A1,D1,IF(VLOOKUP(VLOOKUP(A2,$A$2:B2,2,0),$A$1:B1,2,0)=A2, VLOOKUP(B2,$A$1 : D1,4,0))), MAX($D$1 : D1)+1)

Thấy cũng giống với kết quả

Phan Thế Hiệp · 18/7/25

thanthanhan đã viết:
Tôi cũng xin góp vui 1 công thức, cách làm không được hay như mọi người ở trên
=IFERROR(IF(A2=A1,D1,IF(VLOOKUP(VLOOKUP(A2,$A$2:B2,2,0),$A$1:B1,2,0)=A2,VLOOKUP(B2,$A$11,4,0))),MAX($D$11)+1)

Thấy cũng giống với kết quả
View attachment 308951

Thấy bạn cũng hay xài 365, vậy dùng vầy đi (chôm điều kiện của anh @HieuCD

)

Mã:

=@FILTER(C$1:C1,(($A$1:A1=A2)+($A$1:A1=B2))*(($B$1:B1=B2)+($B$1:B1=A2)),MAX(C$1:C1)+1)

Thân

thanthanhan · 18/7/25

Phan Thế Hiệp đã viết:
Thấy bạn cũng hay xài 365, vậy dùng vầy đi (chôm điều kiện của anh @HieuCD )

Mã:

=@FILTER(C$1:C1,(($A$1:A1=A2)+($A$1:A1=B2))*(($B$1:B1=B2)+($B$1:B1=A2)),MAX(C$1:C1)+1)

Thân

Tôi ít xài 365 lắm, vẫn còn quen kiểu sử dụng của phiên bản cũ.
Cám ơn bạn đã hướng dẫn thêm cho tôi
Chúc mọi người vui vẻ.

Phan Thế Hiệp · 18/7/25

thanthanhan đã viết:
Tôi ít xài 365 lắm, vẫn còn quen kiểu sử dụng của phiên bản cũ.
Cám ơn bạn đã hướng dẫn thêm cho tôi
Chúc mọi người vui vẻ.

Vậy, cố gắng vọc mảng cho vui, bạn sẽ học được nhiều cái lý thú.

Thân

dazkangel · 19/7/25

Bạn thử cách sau nhé:

Mã:

=IFERROR(VLOOKUP("*"&A2&B2&"*",IF({1,0},A$1:A1&B$1:B1&A$1:A1,C$1:C1),2,0),MAX(C$1:C1)+1)

HieuCD · 19/7/25

Dùng hàm Index dể hiểu hơn
=IFERROR(INDEX(C$1:C1,MATCH("*"&A2&B2&"*",A$1:A1&B$1:B1&A$1:A1,0)),MAX(C$1:C1)+1)
Nhấn Ctrl+Shift+Enter

Phan Thế Hiệp · 19/7/25

dazkangel đã viết:
Bạn thử cách sau nhé:

Mã:

=IFERROR(VLOOKUP("*"&A2&B2&"*",IF({1,0},A$1:A1&B$1:B1&A$1:A1,C$1:C1),2,0),MAX(C$1:C1)+1)

Ôi! Ông em "Hắc thiên sứ" mê mẫn 'chân trời mới' nay mới quay về nhà, khà khà. Khỏe không em?

Cái vụ nối cột này nhắc anh nhớ lại vụ Indirect(,0) lấy địa chỉ ô. Áp dụng ý này vui đó em trai.

Chúc em ngày vui
/-*+/

dazkangel · 20/7/25

Phan Thế Hiệp đã viết:
Ôi! Ông em "Hắc thiên sứ" mê mẫn 'chân trời mới' nay mới quay về nhà, khà khà. Khỏe không em?

Cái vụ nối cột này nhắc anh nhớ lại vụ Indirect(,0) lấy địa chỉ ô. Áp dụng ý này vui đó em trai.

Chúc em ngày vui

Em lặn hơi sâu, nhiều kiến thức đã quên rồi anh

Excel my love_1 · 21/7/25

Duy Tùng 9x đã viết:
Office thấp kéo thì bạn thử này xem. Đúng với dữ liệu đó, còn nhiều thì chưa rõ nữa

Mã:

E2=IFNA(LOOKUP(1,0/(MMULT(($A$1:B1=A2)+($A$1:B1=B2),{1;1})),$E$1:E1),MAX($E$1:E1)+1)

Cảm ơn bạn đã giúp đỡ, công thức của bạn đúng rồi. Chúc bạn ngày vui nha

Bài đã được tự động gộp: 21/7/25

HieuCD đã viết:
C2 =IFERROR(LOOKUP(2,1/(($A$1:A1=A2)+($A$1:A1=B2))/(($B$1:B1=B2)+($B$1:B1=A2)),$C$1:C1),MAX($C$1:C1)+1)
Copy xuống . . .

cảm ơn thầy đã giúp đỡ , nay lại được nhìn thấy kiến thức của thầy trong bài giải này, em rất vui
Thầy xưa tóc vẫn pha sương,
Dáng quen năm cũ con đường excel.
Gặp thầy lòng bỗng bâng khuâng,
Ơn sâu năm tháng chẳng ngần phai đi.

Bài đã được tự động gộp: 21/7/25

thanthanhan đã viết:
Tôi cũng xin góp vui 1 công thức, cách làm không được hay như mọi người ở trên
=IFERROR(IF(A2=A1,D1,IF(VLOOKUP(VLOOKUP(A2,$A$2:B2,2,0),$A$1:B1,2,0)=A2, VLOOKUP(B2,$A$1 : D1,4,0))), MAX($D$1 : D1)+1)

Thấy cũng giống với kết quả
View attachment 308951

Cảm ơn bạn, kết quả đúng rồi, thật vui khi được mọi người giúp đỡ nhiệt tình ạ

Bài đã được tự động gộp: 21/7/25

dazkangel đã viết:
Bạn thử cách sau nhé:

Mã:

=IFERROR(VLOOKUP("*"&A2&B2&"*",IF({1,0},A$1:A1&B$1:B1&A$1:A1,C$1:C1),2,0),MAX(C$1:C1)+1)

Cảm ơn bạn nha. Trước mình vẫn theo dõi các bài trả lời của bạn dazkangel (mình đã cảm biết bạn xử lý công thức rất mạnh), nay được bạn trực tiếp ra tay hiệp nghĩa giúp đỡ, mình thấy rất vui. Chúc bạn thật nhiều sức khỏe nhé

Excel my love_1 · 21/7/25

Phan Thế Hiệp đã viết:
Thấy bạn cũng hay xài 365, vậy dùng vầy đi (chôm điều kiện của anh @HieuCD )

Mã:

=@FILTER(C$1:C1,(($A$1:A1=A2)+($A$1:A1=B2))*(($B$1:B1=B2)+($B$1:B1=A2)),MAX(C$1:C1)+1)

Thân

Cảm ơn thầy! Đã lâu lắm rồi kể từ ngày ấy...Nay em được nhìn lại bài viết của thầy ở đây
Cuộc sống thực ngoài kia lắm biến động người lên kẻ xuống, nhưng ở đây vẫn được thấy phong cách trò chuyện gần gũi, đầy tích cực của thầy. Cảm giác giống như là về trường cũ, gặp lại người thầy năm xưa ạ. Mong thầy sức khỏe dồi dào và nhiều niềm vui ạ
Bâng khuâng rảo bước diễn đàn,
User năm cũ vẫn đan sớm chiều.
Thầy xưa tóc đã bạc nhiều,
Nụ cười vẫn ấm như chiều hôm qua

Phan Thế Hiệp · 21/7/25

Excel my love_1 đã viết:
Cuộc sống thực ngoài kia lắm biến động người lên kẻ xuống, nhưng ở đây vẫn được thấy phong cách trò chuyện gần gũi, đầy tích cực của thầy. Cảm giác giống như là về trường cũ, gặp lại người thầy năm xưa ạ. Mong thầy sức khỏe dồi dào và nhiều niềm vui ạ

Cảm ơn những suy nghĩ của bạn về anh em chúng tôi.

Tôi có đáng 'làm thầy làm bà' ai đâu, bạn!
Cứ xem là anh em cùng hội cùng thuyền thì ổn rồi!

Tôi như người đưa đò, ai cần qua sông thì chở, không ai thì ngắm trời mây sông nước làm vui. Chỉ vậy thôi bạn!

Trích câu kết của tác phẩm bất hủ: "Ông lão chèo đò" của soạn giả Viễn Châu, do danh ca Út Trà Ôn thể hiện:
"...Ai dại, ai khôn, rốt cuộc gẫm lại vẫn không bằng đời của lão. Còn trời, còn nước, còn sông, còn cây đa cũ, còn ông chèo đò"
(

Liên kết: https://youtu.be/Hob1EQWBV5o?si=dsXi2tTa0-YymP3z
)

Chúc bạn học vui với GPE
/-*+/

Đánh số cho các cặp số chứng từ và số chứng từ đối ứng (1 người xem)

Người dùng đang xem chủ đề này

Thành viên thường trực

File đính kèm

Zalo 0987841557

Zalo 0987841557

Chuyên gia GPE

-⍟-

Chuyên gia GPE

Thành viên mới

-⍟-

Thành viên mới

-⍟-

<New Horizons>

Chuyên gia GPE

-⍟-

<New Horizons>

Thành viên thường trực

Thành viên thường trực

-⍟-

Thời gian đếm ngược.