Nhờ tính tổng cho từng sản phẩm do từng công ty làm được bằng VBA (1 người xem)

  • Thread starter Thread starter LinDan
  • Ngày gửi Ngày gửi
Liên hệ QC

Người dùng đang xem chủ đề này

Đang trực tuyến: 1 (Thành viên: 0, Khách: 1)
LinDan

LinDan

Thành viên tiêu biểu
Tham gia
8/2/12
Bài viết
412
Được thích
111
Bài này thường ngày tôi làm bằng Pivot table, nay tôi muốn học thêm VBA nhờ các bác làm giúp.

Tonghopdulieu.png


Xin cảm ơn rất nhiều
 

File đính kèm

Lần chỉnh sửa cuối:
Sắp xếp theo thời gian sắp xếp theo bầu chọn

File đính kèm

Upvote 0
Bác Ndu chuyển giúp file đính kèm trên sang xls giúp tôi với, máy của tôi chỉ có Office 2003 nên không chạy được nó.

Tôi theo dõi nhiều bài viết từ trên diễn đàn thấy Dictionary của bác Ndu96081631 rất hay, tôi muốn làm bằng cái này vì như bác nói Dictionary nó giải quyết được cả những bài toán bao hàm cả yếu tố tồn tại hay là không tồn tại, nên tôi rất muốn xem Dic sẽ giải quyết bài này như thế nào? Nếu được phiền các bác làm hộ cho theo phương pháp ấy nhé.
 
Upvote 0
Đã chuyển sang 2003 cho bạn rồi đấy
 

File đính kèm

Upvote 0
Chà chà file này nặng quá, máy của tôi sau khi mở chọn hàm max để tính, không hiểu sao 3 phút rồi mà chưa xong.
 
Upvote 0
LinDan đã viết:
Chà chà file này nặng quá, máy của tôi sau khi mở chọn hàm max để tính, không hiểu sao 3 phút rồi mà chưa xong.
Nhấp chuột vào đây để mở rộng...
Bạn thử file mới này xem thế nào nhé
Code đã được cải tiến thêm rất nhiều. Máy tôi cho ra kết quả trong vòng 0.7 giây với dữ liệu 65000 dòng
 

File đính kèm

Upvote 0
ndu96081631 đã viết:
Bạn thử file mới này xem thế nào nhé
Code đã được cải tiến thêm rất nhiều. Máy tôi cho ra kết quả trong vòng 0.7 giây với dữ liệu 65000 dòng
Nhấp chuột vào đây để mở rộng...
Qua bài transferData_5 của NDU mới thấy lợi hại của việc khai báo số dòng và cột của mảng. Khai dư quá thì chậm hơn khai vừa đủ và nếu cần thì dùng redim.
Thử dùng thêm 1 for để lấy dic.count mà khai báo nhưng mà chậm hơn là redim với dữ liệu lớn.
Cám ơn NDU.
 
Upvote 0
Nhìn thấy code của các cao thủ mà mình thấy thẹn quá, nhưng làm rồi nên cũng gởi lên góp vui. Code mình viết là chỉ để cho anh em mới học VBA, nên chạy chậm tí

Private Sub CommandButton1_Click()
Dim ketqua, ketqua1, r, r1, c, n
Application.ScreenUpdating = False
For r1 = 2 To 5
For c = 6 To 8
n = [a65000].End(3).Row
For r = 2 To n
If Cells(r, 1) & Cells(r, 2) = Cells(r1, 5) & Cells(1, c) Then
ketqua = Cells(r, 3)
ketqua1 = ketqua1 + ketqua
End If
Next
Cells(r1, c) = ketqua1
ketqua1 = 0
Next
Next
Application.ScreenUpdating = True
End Sub
 

File đính kèm

Upvote 0
Xin hỏi 2 Sub nên để ở hai Module hay là để trên cùng một Module

Tôi thấy trên diễn đàn, có bài toán bao gồm 2 Sub trở lên, thường có 2 phương án:

- Từng Sub trên một Module (Module1, Module 2...)
- Gộp chung các Sub vào trong 1 Module

Xin hỏi trong 2 cách trên thì cách nào thuận tiện hơn.
 
Upvote 0
LinDan đã viết:
Tôi thấy trên diễn đàn, có bài toán bao gồm 2 Sub trở lên, thường có 2 phương án:

- Từng Sub trên một Module (Module1, Module 2...)
- Gộp chung các Sub vào trong 1 Module

Xin hỏi trong 2 cách trên thì cách nào thuận tiện hơn.
Nhấp chuột vào đây để mở rộng...

Bất luận Sub dài hay ngắn Tôi thường viết mỗi Sub một Module và sửa tên Module thành tên riêng (tương tự như đổi tên Sheet) để cho dễ tìm. Ví dụ Module1 chứa Sub TongCong() thì đổi Module1 =TongCong
 
Upvote 0
Bài toán này trông thế mà phức tạp gớm

PHP: 
Sub TaoBC()
Dim endR&, i&, iR&, iC&, nR&, nC&
Dim Arr, ArrKQ
Dim Tmp01$, Tmp02$
Dim Dic01 As Object, Dic02 As Object
Set Dic01 = CreateObject("Scripting.Dictionary")
Set Dic02 = CreateObject("Scripting.Dictionary")
With Sheets("Data")
  .AutoFilterMode = False
  endR = .Cells(65000, 1).End(3).Row
  Arr = .Range(.Cells(2, 1), .Cells(endR, 3)).Value
End With
ReDim ArrKQ(1 To UBound(Arr), 1 To 200)
iR = 1: iC = 1
For i = 1 To UBound(Arr)
  If Len(CStr(Arr(i, 1))) > 0 Then
    If Len(CStr(Arr(i, 2))) > 0 Then
      Tmp01 = CStr(Arr(i, 1))
      If Not Dic01.Exists(Tmp01) Then
        iR = iR + 1
        Dic01.Add Tmp01, iR
        ArrKQ(iR, 1) = Tmp01
      End If
      Tmp02 = Arr(i, 2)
      If Not Dic02.Exists(Tmp02) Then
        iC = iC + 1
        Dic02.Add Tmp02, iC
        ArrKQ(1, iC) = Tmp02
      End If
      nR = Dic01.Item(Tmp01)
      nC = Dic02.Item(Tmp02)
      ArrKQ(nR, nC) = ArrKQ(nR, nC) + Arr(i, 3)
    End If
  End If
Next i
If iR And iC Then
  With Sheets("sheet2")
    .Cells.ClearContents
    .[A1].Resize(iR, iC) = ArrKQ
  End With
End If
Erase Arr, ArrKQ
Set Dic01 = Nothing: Set Dic02 = Nothing
End Sub

Những dòng khai báo trên thì không vấn đề gì, nhưng đến công thức mấu chốt nhất của bài thì phức tạp đây (hình dung mãi nhưng chưa hiểu lắm)
ArrKQ(nR, nC) = ArrKQ(nR, nC) + Arr(i, 3)

Nhờ các pác giải thích dùm công thức trên, cho tôi hình dung cụ thể khi sau khi i chạy đến 12 (tức chạy đến Ô A13) thì ArrKQ(nR,nC)=Arr(2,2) chăng ?
(nR và iR hình như là một tức nR=ỉR? nhưng hình như không phải)
 
Lần chỉnh sửa cuối:
Upvote 0
LinDan đã viết:
Tôi thấy trên diễn đàn, có bài toán bao gồm 2 Sub trở lên, thường có 2 phương án:

- Từng Sub trên một Module (Module1, Module 2...)
- Gộp chung các Sub vào trong 1 Module

Xin hỏi trong 2 cách trên thì cách nào thuận tiện hơn.
Nhấp chuột vào đây để mở rộng...
Bạn muốn đặt sao tùy thích. Riêng tôi, nếu chỉ có 2 Sub thì chẳng việc gì chia ra 2 module
Còn nếu có nhiều sub, tôi sẽ cho những sub có chung 1 công dụng vào 1 module... Giống như file điều khiển đồng hồ này:
http://www.giaiphapexcel.com/forum/showthread.php?39729-Tạo-quả-lắc-(đồng-hồ)-theo-chu-kỳ-1-giây&p=281099#post281099
tôi cho các sub điều khiển kim đồng hồ vào 1 sub, các sub điều khiển âm thanh vào 1 sub với mục đích phân loại cho dể tìm... Thế thôi!
------------------------------
LinDan đã viết:
Bài toán này trông thế mà phức tạp gớm


Những dòng khai báo trên thì không vấn đề gì, nhưng đến công thức mấu chốt nhất của bài thì phức tạp đây (hình dung mãi nhưng chưa hiểu lắm)
ArrKQ(nR, nC) = ArrKQ(nR, nC) + Arr(i, 3)

Nhờ các pác giải thích dùm công thức trên, cho tôi hình dung cụ thể khi sau khi i chạy đến 12 (tức chạy đến Ô A13) thì ArrKQ(nR,nC)=Arr(2,2) chăng ?
(nR và iR hình như là một tức nR=ỉR? nhưng hình như không phải)
Nhấp chuột vào đây để mở rộng...
- Vòng lập duyệt từ trên xuống
- "Quăng" từng em của cột A vào Dic1 và từng phần tử của cột B vào Dic2 (nếu nó chưa tồn tại)
- Ngay tại thời điểm này, xác định vị trí nR và nC chính là vị trí dòng, cột của mảng ArrKQ
- ArrKQ(nR, nC) chính là vị trí mà ta cần cộng dồn vào bằng cách lấy chính nó cộng với dòng tương ứng (dòng i) của cột C
 
Lần chỉnh sửa cuối:
Upvote 0
Nhờ các pác giải thích dùm công thức trên, cho tôi hình dung cụ thể khi sau khi i chạy đến 12 (tức chạy đến Ô A13) thì ArrKQ(nR,nC)=Arr(2,2) chăng ? (nR và iR hình như là một tức nR=ỉR? nhưng hình như không phải)
Nhấp chuột vào đây để mở rộng...

* nR và iR khác nhau chứ bạn:

- nR là số thứ tự (Item) của các phần tử trong Dic, các phần tử trong Dic.01 bài này chính là các Công ty mà; bạn cứ tưởng tượng Item nó như là số thứ tự để quản lý công văn đến hàng ngày vậy, mỗi công văn được theo dõi bằng 1 mã số duy nhất để tiện tra cứu. Ở bài này số công văn tìm thấy đầu tiên (Công ty A) được đánh số bắt đầu là 2, khi i = 12 gặp lại Công ty A nghĩa là Công ty A đã được đánh số theo dõi là 2 rồi thì không đánh lại nữa (tức nR=2).

- Mặt khác: iR khi sau khi i chạy đến 12 thì iR=4 (do nó chạy qua 3 ô khác nhau, mỗi khi kiểm tra một ô nào đó kết quả không nằm trong Dic thì iR nó tự động tăng thêm một đơn vị, cộng với 1 đơn vị được khuyễn mãi trước khi chạy, như vậy tổng cộng iR=1+3=4).

Trong số các bài trước được sư phụ Ndu chỉ, bài này có lẽ là bài tiêu biểu nó lên vai trò quan trọng của thành phần Item trong Dic.Add Tmp, Item
 
Lần chỉnh sửa cuối:
Upvote 0
Bác Thu Nghi giải thích giúp
With Sheets("Data")
.AutoFilterMode = False
có tác dụng gì thế? Tại sao cần dùng đến nó hả bác
 
Lần chỉnh sửa cuối:
Upvote 0
LinDan đã viết:
Bác Thu Nghi giải thích giúp
With Sheets("Data")
.AutoFilterMode = False
có tác dụng gì thế? Tại sao cần dùng đến nó hả bác
Nhấp chuột vào đây để mở rộng...
Vì code của bác ấy có dùng thuộc tính End(xlUP), mục đích xác định dòng cuối cùng có dữ liệu... Và cái thằng End(xlUP) này sẽ bị sai khi sheet đang có AutoFilter
Chính vì lẽ đó, bác ấy hũy chế độ AutoFilter trước khi thực thi tính toán
Giải thích thêm: Range("A60000").End(xlUp) là tương đương với động tác đặt con trỏ chuột vào cell A60000 rồi bấm tổ hợp phím Ctrl + mũi tên lên
 
Upvote 0
Xin thày Ndu giải thích hộ đoạn If Len(CStr(Arr(i, 1))) > 0 Then tại sao không dùng là If Arr(i, 1) <> "" Then vừa đơn giản, máy đỡ phải chuyển đổi >> nhanh hơn.
 
Upvote 0
LinDan đã viết:
Xin thày Ndu giải thích hộ đoạn If Len(CStr(Arr(i, 1))) > 0 Then tại sao không dùng là If Arr(i, 1) <> "" Then vừa đơn giản, máy đỡ phải chuyển đổi >> nhanh hơn.
Nhấp chuột vào đây để mở rộng...
Theo kinh nghiệm tối ưu hóa code thì việc so sánh số lượng kí tự trong chuỗi sẽ nhanh hơn là so sánh trực tiếp chuỗi đó, tức là nếu bạn so sánh giữa Len(a)=0 và a="" thì Len(a)=0 sẽ nhanh hơn.
 
Upvote 0
Tại sao Code của tôi chạy ra kết quả sai nhỉ

Do chưa có kinh nghiệm, sau khi viết Code khi chạy vẫn ra kết quả nhưng tổng hợp không đúng, phiền mọi người xem hộ tôi, chỉ tôi nhầm ở đâu.

PHP: 
Sub Tonghop()
Dim DL(), eR As Long, i As Long, j As Long, Tmp1, Tmp2, Dong, Cot

With Sheets("Sheet1")
eR = .[C65000].End(xlUp).Row
DL = .Range("A2:C" & eR).Value
ReDim KQ(1 To UBound(DL, 1) + 1, 1 To UBound(DL, 1) + 1)
Set Dic1 = CreateObject("Scripting.Dictionary")
Set Dic2 = CreateObject("Scripting.Dictionary")
n = 1
m = 1
For i = 1 To UBound(DL, 1)
    If DL(i, 1) <> "" Then
      Tmp1 = DL(i, 1)
        If Not Dic1.Exists(Tmp1) Then
          n = n + 1
          Dic1.Add Tmp1, n
          Dong = Dic1.Item(Tmp1)
          KQ(n, 1) = Tmp1
    If DL(i, 2) <> "" Then
      Tmp2 = DL(i, 2)
        If Not Dic2.Exists(Tmp2) Then
          m = m + 1
          Dic2.Add Tmp2, m
          Cot = Dic2.Item(Tmp2)
          KQ(1, m) = Tmp2
KQ(Dong, Cot) = KQ(Dong, Cot) + DL(i, 3)
End If
End If
End If
End If
Next
End With

With Sheets("Sheet2")
.Cells.ClearContents
.[A1].Resize(Dong, Cot).Value = KQ
End With

End Sub
 
Lần chỉnh sửa cuối:
Upvote 0
LinDan đã viết:
Do chưa có kinh nghiệm, sau khi viết Code khi chạy vẫn ra kết quả nhưng tổng hợp không đúng, phiền mọi người xem hộ tôi, chỉ tôi nhầm ở đâu.

PHP: 
Sub Tonghop()
Dim DL(), eR As Long, i As Long, j As Long, Tmp1, Tmp2, Dong, Cot

With Sheets("Sheet1")
eR = .[C65000].End(xlUp).Row
DL = .Range("A2:C" & eR).Value
ReDim KQ(1 To UBound(DL, 1) + 1, 1 To UBound(DL, 1) + 1)
Set Dic1 = CreateObject("Scripting.Dictionary")
Set Dic2 = CreateObject("Scripting.Dictionary")
n = 1
m = 1
For i = 1 To UBound(DL, 1)
    If DL(i, 1) <> "" Then
      Tmp1 = DL(i, 1)
        If Not Dic1.Exists(Tmp1) Then
          n = n + 1
          Dic1.Add Tmp1, n
          Dong = Dic1.Item(Tmp1)
          KQ(n, 1) = Tmp1
    If DL(i, 2) <> "" Then
      Tmp2 = DL(i, 2)
        If Not Dic2.Exists(Tmp2) Then
          m = m + 1
          Dic2.Add Tmp2, m
          Cot = Dic2.Item(Tmp2)
          KQ(1, m) = Tmp2
KQ(Dong, Cot) = KQ(Dong, Cot) + DL(i, 3)
End If
End If
End If
End If
Next
End With

With Sheets("Sheet2")
.Cells.ClearContents
.[A1].Resize(Dong, Cot).Value = KQ
End With

End Sub
Nhấp chuột vào đây để mở rộng...
Sai quá trời luôn!
Bạn đặt sai vị trí nhiều quá.... Hãy so sánh với cái tôi sửa lại nhé:
PHP: 
Sub Tonghop()
  Dim DL, eR As Long, i As Long, n As Long, m As Long, Tmp1, Tmp2, Dong, Cot
  Dim Dic1 As Object, Dic2 As Object, KQ()
  With Sheets("Sheet1")
    DL = .Range(.[A2], .[C65000].End(xlUp)).Value
  End With
  ReDim KQ(1 To UBound(DL, 1), 1 To UBound(DL, 1))
  Set Dic1 = CreateObject("Scripting.Dictionary")
  Set Dic2 = CreateObject("Scripting.Dictionary")
  n = 1
  m = 1
  For i = 1 To UBound(DL, 1)
    If DL(i, 1) <> "" And DL(i, 2) <> "" Then
      Tmp1 = DL(i, 1)
      If Not Dic1.Exists(Tmp1) Then
        n = n + 1
        Dic1.Add Tmp1, n
        
        KQ(n, 1) = Tmp1
      End If
      Tmp2 = DL(i, 2)
      If Not Dic2.Exists(Tmp2) Then
        m = m + 1
        Dic2.Add Tmp2, m
        KQ(1, m) = Tmp2
      End If
      Dong = Dic1.Item(Tmp1)
      Cot = Dic2.Item(Tmp2)
      KQ(Dong, Cot) = KQ(Dong, Cot) + DL(i, 3)
    End If
  Next
  With Sheets("Sheet2")
    .Cells.ClearContents
    .[A1].Resize(Dong, Cot).Value = KQ
  End With
End Sub
 
Upvote 0
Code của thày chạy ra nó vẫn không được kết quả Sản phẩm 3 (chỉ ra sản phẩm 1 và 2) thôi.

Bản thân tôi cứ tưởng có 4 If thì có 4 End If là được, 4 End If này đặt đâu cũng thế vì không thấy lỗi.
 
Lần chỉnh sửa cuối:
Upvote 0
LinDan đã viết:
Code của thày chạy ra nó vẫn không được kết quả Sản phẩm 3 (chỉ ra sản phẩm 1 và 2) thôi.

Bản thân tôi cứ tưởng có 4 If thì có 4 End If là được, 4 End If này đặt đâu cũng thế vì không thấy lỗi.
Nhấp chuột vào đây để mở rộng...
Ah.. sơ ý!
Sửa chổ này:
.[A1].Resize(Dong, Cot).Value = KQ
Thành:
.[A1].Resize(n, m).Value = KQ
 
Upvote 0
Bản thân chưa phân biệt được 2 Code này khác nhau ở điểm gì, mong bác Ndu chỉ giúp
Code đúng:
PHP: 
Sub Tonghop()
  Dim DL, eR As Long, i As Long, n As Long, m As Long, Tmp1, Tmp2, Dong, Cot
  Dim Dic1 As Object, Dic2 As Object, KQ()
  With Sheets("Sheet1")
    DL = .Range(.[A2], .[C65000].End(xlUp)).Value
  End With
  ReDim KQ(1 To UBound(DL, 1), 1 To UBound(DL, 1))
  Set Dic1 = CreateObject("Scripting.Dictionary")
  Set Dic2 = CreateObject("Scripting.Dictionary")
  n = 1
  m = 1
  For i = 1 To UBound(DL, 1)
    If DL(i, 1) <> "" And DL(i, 2) <> "" Then
      Tmp1 = DL(i, 1)
      If Not Dic1.Exists(Tmp1) Then
        n = n + 1
        Dic1.Add Tmp1, n
        
        KQ(n, 1) = Tmp1
      End If
      Tmp2 = DL(i, 2)
      If Not Dic2.Exists(Tmp2) Then
        m = m + 1
        Dic2.Add Tmp2, m
        KQ(1, m) = Tmp2
      End If
      Dong = Dic1.Item(Tmp1)
      Cot = Dic2.Item(Tmp2)
      KQ(Dong, Cot) = KQ(Dong, Cot) + DL(i, 3)
    End If
  Next
  With Sheets("Sheet2")
    .Cells.ClearContents
    .[A1].Resize(m, n).Value = KQ
  End With
End Sub
Code tính sai:
PHP: 
Sub Tonghop()
  Dim DL, eR As Long, i As Long, n As Long, m As Long, Tmp1, Tmp2, Dong, Cot
  Dim Dic1 As Object, Dic2 As Object, KQ()
  With Sheets("Sheet1")
    DL = .Range(.[A2], .[C65000].End(xlUp)).Value
  End With
  ReDim KQ(1 To UBound(DL, 1), 1 To UBound(DL, 1))
  Set Dic1 = CreateObject("Scripting.Dictionary")
  Set Dic2 = CreateObject("Scripting.Dictionary")
  n = 1
  m = 1
  For i = 1 To UBound(DL, 1)
    If DL(i, 1) <> "" And DL(i, 2) <> "" Then
      Tmp1 = DL(i, 1)
      If Not Dic1.Exists(Tmp1) Then
        n = n + 1
        Dic1.Add Tmp1, n
        Dong = Dic1.Item(Tmp1)
        KQ(n, 1) = Tmp1
      End If
      Tmp2 = DL(i, 2)
      If Not Dic2.Exists(Tmp2) Then
        m = m + 1
        Dic2.Add Tmp2, m
        Cot = Dic2.Item(Tmp2)
        KQ(1, m) = Tmp2
      End If
      
      KQ(Dong, Cot) = KQ(Dong, Cot) + DL(i, 3)
    End If
  Next
  With Sheets("Sheet2")
    .Cells.ClearContents
    .[A1].Resize(m, n).Value = KQ
  End With
End Sub

Ghi chú: 2 Code trên khác nhau là do thứ tự đặt 2 lệnh vị trí khác nhau
PHP: 
            Dong = Dic1.Item(Tmp1)
      Cot = Dic2.Item(Tmp2)
nhưng chưa hình dung được khi hoạt động thì nó khác nhau như thế nào nhỉ?
 
Lần chỉnh sửa cuối:
Upvote 0
LinDan đã viết:
Ghi chú: 2 Code trên khác nhau là do thứ tự đặt 2 lệnh vị trí khác nhau
PHP: 
            Dong = Dic1.Item(Tmp1)
      Cot = Dic2.Item(Tmp2)
nhưng chưa hình dung được khi hoạt động thì nó khác nhau như thế nào nhỉ?
Nhấp chuột vào đây để mở rộng...
- Khi bạn duyệt qua vòng lập từ trên xuống, bạn Add từng cái tmp1 vào Dic1 và tmp2 vào Dic2, đúng không?
- tmp1 và tmp2 chỉ Add được khi Dictionary chưa tồn tại mấy thằng em này, đúng không?
- Nhưng cho dù là Add được vào Dictionary hay không thì bạn cũng phải xác định Dong, Cot để cộng dồn vào KQ
- Vậy có phải là việc xác định Dong, Cot và cộng dồn này phải nằm ngoài IF không?
Chẳng lẽ "chưa tồn tại" thì mới cộng dồn còn "tồn tại" rồi, khỏi cộng?
 
Upvote 0
Vâng vâng, chỗ này có khi tôi chưa hiểu lắm về Dic thì phải, nhất trí KQ phải cộng sau End If rồi, nhưng Dong và Cot có thể đã xác định trước End If cũng được chứ hả bác.

Xin bác hộ cho tôi hiểu chỗ này với.
 
Upvote 0
LinDan đã viết:
Vâng vâng, chỗ này có khi tôi chưa hiểu lắm về Dic thì phải, nhất trí KQ phải cộng sau End If rồi, nhưng Dong và Cot có thể đã xác định trước End If cũng được chứ hả bác.

Xin bác hộ cho tôi hiểu chỗ này với.
Nhấp chuột vào đây để mở rộng...
KQ muốn cộng dồn được thì phải xác định Dong, Cot trước, đúng không? Vì KQ(Dong, Cot) = KQ(Dong, Cot) + DL(i, 3)
Vậy, nếu cho biến Dong, Cot vào bên trong IF, ở trường hợp IF không thỏa điều kiện thì hóa ra sẽ lấy Dong, Cot của lần trước à?
 
Upvote 0
Thế thì 2 cách viết như sau là hoàn toàn khác nhau hả bác. Tôi cứ tưởng nó giống nhau chứ
PHP: 
If Not Dic2.Exists(Tmp2) Then
        m = m + 1
        Dic2.Add Tmp2, m
        KQ(1, m) = Tmp2
      Cot = Dic2.Item(Tmp2)
End If

và cách viết
PHP: 
If Not Dic2.Exists(Tmp2) Then
        m = m + 1
        Dic2.Add Tmp2, m
        KQ(1, m) = Tmp2
      End If
            Cot = Dic2.Item(Tmp2)
 
Upvote 0
Cái này thày nói quá rõ ở trên rồi mà, bây giờ ta bàn đến trường hợp khi duyệt qua gặp lại phần tử trước nhé.

Cách viết này
PHP: 
If Not Dic2.Exists(Tmp2) Then
        m = m + 1
        Dic2.Add Tmp2, m
        KQ(1, m) = Tmp2
      End If
            Cot = Dic2.Item(Tmp2)

có nghĩa là sau khi họp, xem xét xong (sau khi End If) thấy Tmp2 này đã gặp rồi>> nó vẫn phải lấy mã số cũ.
Cách viết này m và Cot độc lập nhau. Ví dụ khi i=11 thì m=5 nhưng i = 2

Do dòng Cot = Dic2.Item(Tmp2) nằm ngoài lệnh If nên lúc này nó chính là Item của Tmp2 (mới)
-------------------------
Còn cách viết này
PHP: 
If Not Dic2.Exists(Tmp2) Then
        m = m + 1
        Dic2.Add Tmp2, m
        KQ(1, m) = Tmp2
      Cot = Dic2.Item(Tmp2)
End If
lúc này Tmp2 do không nhét được vào, do Cot nằm trong If nên nó không lấy được Item của Tmp2 mới>> đành phải lấy Item của Tmp2 cũ, cách viết này thì Cot luôn luôn bằng m (cột =m). Ví dụ khi i=11 thì m=5, cot=5.

Cái này nói rõ hơi khó nhưng bạn cứ chịu khó tưởng tượng sẽ ra thôi.
 
Lần chỉnh sửa cuối:
Upvote 0
LinDan đã viết:
Thế thì 2 cách viết như sau là hoàn toàn khác nhau hả bác. Tôi cứ tưởng nó giống nhau chứ
PHP: 
If Not Dic2.Exists(Tmp2) Then
        m = m + 1
        Dic2.Add Tmp2, m
        KQ(1, m) = Tmp2
      Cot = Dic2.Item(Tmp2)
End If

và cách viết
PHP: 
If Not Dic2.Exists(Tmp2) Then
        m = m + 1
        Dic2.Add Tmp2, m
        KQ(1, m) = Tmp2
      End If
            Cot = Dic2.Item(Tmp2)
Nhấp chuột vào đây để mở rộng...

2 cách viết đương nhiên khác nhau, VBA sẽ làm việc theo thứ tự trên xuống dưới. Nếu với cách viết 1 của bạn thì là điều kiện thỏa thì mới thực hiện, còn cách thứ 2 thì dù thỏa hay không cũng làm vì nó được đặt ngoài vòng If rồi. Bạn có thể hiểu rõ hơn bằng cách sử dụng F8 đấy, khi bạn nhấn F8 thì nó sẽ thực hiện từng dòng lệnh một và bạn sẽ thấy rõ nó làm cái gì làm cái gì, khi đó bạn có thể hiểu hơn về cách vận hành của chương trình
 
Upvote 0
Giải thích như bác kyo là chuẩn, dễ hiểu quá rồi.
 
Upvote 0
trungvdb đã viết:
Giải thích như bác kyo là chuẩn, dễ hiểu quá rồi.
Nhấp chuột vào đây để mở rộng...

Tôi phải công nhận bạn cũng là một thiên tài! Chưa rành về IF, WITH, ... , các sự kiện của Sheet, ... vậy mà bạn đã học gần như có thể làm được các vụ xử lý trong mảng rồi, đặc biệt là Dictionary.

Bạn đã chọn một trong những con đường khó nhất để đi trong lập trình VBA. Xin chúc mừng bạn!
 
Upvote 0
Bạn phải đăng nhập hoặc đăng ký để trả lời bài viết tại đây.

Bài viết mới nhất

D
Lọc các ô có dữ liệu trùng nhau trong một cột. Xin chỉ giúp
Trả lời
3
Đọc
154
dhl1986
D
N
  • Question Question
Giúp thu gọn sắp xếp bảng dữ liệu liệu về dạng cột
Trả lời
7
Đọc
154
Zizi One
Zizi One
N
Tìm công thức để lọc theo 2 điều kiện (1 người xem)
Trả lời
2
Đọc
41
ntct129
N
T
VBA LẤY THÔNG TIN TRÊN TỜ KHAI NHẬP KHẨU
Trả lời
3
Đọc
178
DeTong
D
Nguyễn Duy Tuân
  • Dán lên cao
Phiên bản mới Add-in A-Tools AI v10 (2024)
    • Thích
Trả lời
59
Đọc
8K
Nguyễn Duy Tuân
Nguyễn Duy Tuân
Nguyễn Duy Tuân
Nói để AI thực hiện; Tạo văn bản từ giọng nói trong Excel và Add-in A-Tools (1 người xem)
    • Thích
Trả lời
0
Đọc
39
Nguyễn Duy Tuân
Nguyễn Duy Tuân
nguyenlinhit
Giúp đỡ giải pháp áp dụng công thức DAX vào trường hợp sau
Trả lời
2
Đọc
60
nguyenlinhit
nguyenlinhit
GPE-Trợ Lý
MỪNG NGÀY NHÀ GIÁO VIỆT NAM 20/11/2024
    • Thích
    • Yêu thích
Trả lời
3
Đọc
466
PhanTuHuong
PhanTuHuong
ninhnv.ctt49
Nhờ Cao Nhân Giúp Về File Quản lý Văn Phòng Phẩm
Trả lời
3
Đọc
91
ninhnv.ctt49
ninhnv.ctt49
Trungvt3
File excel bị ẩn các công cụ trên tab khác (như data, insert...)
Trả lời
1
Đọc
60
befaint
befaint
N
Thuế thu nhập cá nhân
    • Chấp nhận
Trả lời
2
Đọc
121
Phan Thế Hiệp
Phan Thế Hiệp
V
Nhờ mọi người chỉ giúp e VBA này (1 người xem)
Trả lời
1
Đọc
57
BuiQuangThuan
B
K
Điền giá trị ô thay vì địa chỉ ô
Trả lời
0
Đọc
41
kamikaze11
K
Nguyenkhang2404
giúp đỡ lọc dữ liệu nâng cao
Trả lời
10
Đọc
213
Phuocam
Phuocam
ongke0711
  • Question Question
Tải hóa đơn điện tử (https://hoadondientu.gdt.gov.vn/) Excel Vba
    • Thích
    • Yêu thích
    • Cảm ơn
3 4 5
Trả lời
401
Đọc
48K
ongke0711
ongke0711
N
Tạo file lưu trữ dữ liệu tự động trên excel.
Trả lời
13
Đọc
405
LOGANWover
L
Tienvinh191
  • Question Question
Nhờ viết Code lấy dữ liệu tờ khai hải quan vào bảng tổng hợp
    • Thích
Trả lời
29
Đọc
3K
ThanhNgoc26100
T
S
cần xử lý dữ liệu trùng nhau bằng VBA
    • Cười
Trả lời
10
Đọc
362
sonminhtran
S
Gà Con yêu VBA
Mở Pass file excel phiên bản .xlsx , xlsm, xlsb
Trả lời
9
Đọc
510
Gà Con yêu VBA
Gà Con yêu VBA
Ả
Cách tạo list Data validation không qua trung gian
Trả lời
46
Đọc
7K
thuytrangbp28
T
Xem thêm…

Thành viên có số lượng bài viết cao nhất tháng

Thành viên có điểm tương tác cao nhất tháng

Thời gian đếm ngược.

000
Ngày
00
Giờ
00
phút
00
giây
Thân mời tham dự sự kiện sinh nhật GPE 2025
Back
Top Bottom