Tìm giá trị: thỏa mãn 2 điều kiện trong 1 vùng dữ liệu ? (1 người xem)

[imex.tb]

Mọi người giúp Em với !!!
E cần đưa dữ liệu ở sheet "Dữ liệu" vòa Sheet "Tổng Hợp" để làm bảng tổng hợp Nhập Kho theo từng Phiếu Nhập Kho theo Mã NPL của từng Phiếu Nhập Kho mà bên kế toán kho cung cấp.
Em cảm ơn !!!
E bổ sung File đính kèm ạ

 

[ppc0312]

Mọi người giúp Em với !!!
E cần đưa dữ liệu ở sheet "Dữ liệu" vòa Sheet "Tổng Hợp" để làm bảng tổng hợp Nhập Kho theo từng Phiếu Nhập Kho theo Mã NPL của từng Phiếu Nhập Kho mà bên kế toán kho cung cấp.
Em cảm ơn !!!
View attachment 228994View attachment 228996

Toàn hình ảnh (hình) thế này, ai làm (nên upload cả file excel lên)? Vì đây không phải diễn đàn xử lý ảnh (hình)
Và nên giải thích rõ câu hỏi nhu cầu, đôi khi cần cả kết quả (tính thủ công) mong muốn
Tóm lại, Khi đặt câu hỏi phải làm sao cho người giúp có đủ điều kiện để giúp và hiểu câu hỏi nhanh nhất có thể.

 

[imex.tb]

Vâng E vừa load file lên rồi ạ. Cảm ơn bác nhắc nhở

 

[ppc0312]

Với ô E8
Nếu version Excel 2007 trở lên thì
=IFERROR(LOOKUP(2,1/('Du liệu'!$B$2:$B$1000='Tổng Hợp'!E$6)/('Du liệu'!$C$2:$C$1000='Tổng Hợp'!$A8),'Du liệu'!$D$2:$D$1000),0)

Còn nếu từ Excel 2003 hay trước đó thì dùng
=LOOKUP(9.9E+307,CHOOSE({1;2},0,LOOKUP(2,1/('Du liệu'!$B$2:$B$1000='Tổng Hợp'!E$6)/('Du liệu'!$C$2:$C$1000='Tổng Hợp'!$A8),'Du liệu'!$D$2:$D$1000)))

 

[imex.tb]

E cảm ơn bác nhiều. Nhưng có trưởng hợp 1 NPL lặp lại 2 hoặc 3 lần trong cùng 1 phiếu Nhập kho thì Sẽ bị thiếu dữ liệu.
Như ví dụ này. Bác nghiên cứu hộ E cái. E cảm ơn bác

 

[ppc0312]

E cảm ơn bác nhiều. Nhưng có trưởng hợp 1 NPL lặp lại 2 hoặc 3 lần trong cùng 1 phiếu Nhập kho thì Sẽ bị thiếu dữ liệu.
Như ví dụ này. Bác nghiên cứu hộ E cái. E cảm ơn bác
View attachment 228998

Nhưng bạn dụng version Excel nào?
Muốn tính tổng? hay sao?
Nếu là tổng thì nên dùng SUMIFS, hoặc SUMPRODUCT
----------------------------------------------------------------------------
E8
=SUMIFS('Du liệu'!$D$2:$D$1000,'Du liệu'!$A$2:$A$1000,'Tổng Hợp'!E$3,'Du liệu'!$C$2:$C$1000,'Tổng Hợp'!$A8,'Du liệu'!$B$2:$B$1000,E$6)

hoặc
E8
=SUMPRODUCT('Du liệu'!$D$2:$D$1000,('Du liệu'!$A$2:$A$1000='Tổng Hợp'!E$3)*('Du liệu'!$C$2:$C$1000='Tổng Hợp'!$A8)*('Du liệu'!$B$2:$B$1000=E$6)

Nếu bỏ điều kiện Số TKHQ thì bỏ phần cột A : A