Viết hàm IF với điều kiện trong khoảng (1 người xem)

[Hoangquyenbong]

Em xin chào cả nhà ạ !
Em xin nhờ cả nhà viết giúp em hàm IF với điều kiện trong khoảng, chi tiết em đã ghi chú trong file đính kèm ạ.
Rất mong nhận được sự giúp đỡ của cả nhà ạ.
Em xin chân thành cảm ơn !

 

[excel_lv1.5]

Em xin chào cả nhà ạ !
Em xin nhờ cả nhà viết giúp em hàm IF với điều kiện trong khoảng, chi tiết em đã ghi chú trong file đính kèm ạ.
Rất mong nhận được sự giúp đỡ của cả nhà ạ.
Em xin chân thành cảm ơn !

Nằm trong khoảng là sao bạn?

 

[Hoangquyenbong]

Nằm trong khoảng là sao bạn?

Mình có giải thích chi tiết trong file đính kèm bạn ạ. vì vừa nhìn số liệu vừa đọc chú thích sẽ dễ hiểu hơn bạn ạ.

 

[Ba Tê]

Em xin chào cả nhà ạ !
Em xin nhờ cả nhà viết giúp em hàm IF với điều kiện trong khoảng, chi tiết em đã ghi chú trong file đính kèm ạ.
Rất mong nhận được sự giúp đỡ của cả nhà ạ.
Em xin chân thành cảm ơn !

Bạn đã liệt kê ra được cả chục cái "Nếu" thì cứ dựa vào đó mà viết "IF".
Ví dụ ô P4:

=IF(SUM(B4:O4)=12;IF(COUNT(J4:O4)=0;$R$3;$S$3);IF(SUM(B4:O4)=18;IF(COUNT(J4:O4)=0;$R$4;$S$4);IF(SUM(B4:O4)=24;IF(COUNT(J4:O4)=0;$R$5;$S$5))))

Chờ các bạn khác "túm gọn".

 

[Hoangquyenbong]

Bạn đã liệt kê ra được cả chục cái "Nếu" thì cứ dựa vào đó mà viết "IF".
Ví dụ ô P4:

=IF(SUM(B4:O4)=12;IF(COUNT(J4:O4)=0;$R$3;$S$3);IF(SUM(B4:O4)=18;IF(COUNT(J4:O4)=0;$R$4;$S$4);IF(SUM(B4:O4)=24;IF(COUNT(J4:O4)=0;$R$5;$S$5))))

Cháu cảm ơn bác ạ,
Cháu cứ hý hoáy mãi mà không chuyển nó sang được để viết "IF" cho nó chạy ra kết quả đúng bác ạ.

 

[Ba Tê]

Cháu cảm ơn bác ạ,
Cháu cứ hý hoáy mãi mà không chuyển nó sang được để viết "IF" cho nó chạy ra kết quả đúng bác ạ.

Thì tôi cũng đọc từng cái "Nếu" của bạn rồi chuyển thành "IF" thôi.
Chủ yếu là kết quả có đúng hay chưa thôi.

 

[Hoangquyenbong]

Thì tôi cũng đọc từng cái "Nếu" của bạn rồi chuyển thành "IF" thôi.
Chủ yếu là kết quả có đúng hay chưa thôi.

Dạ cháu cảm ơn bác,
bác viết cho cháu đúng từ câu trả lời trước của bác rồi ạ.

 

[Phan Thế Hiệp]

Chờ các bạn khác "túm gọn".

Thấy công thức của anh "túm ý" các điều kiện hay quá! tức cộng toàn bộ ô và chỉ cần đếm từ J là xử lý "đẹp".
Nên để em tiếp nối "túm gọn" lấy từ "guột" công thức của anh ra như sau:

P4=OFFSET($R$2,MATCH(SUM(B4:O4),{12,18,24}),COUNT(J4:O4)>0)

Enter, fill xuống.

Chúc anh ngày vui.

 

[huuthang_bd]

Còn cái còn lại

 

[Phan Thế Hiệp]

Còn cái còn lại

Do mấy sếp thích "phết phẩy" nên phải thêm "phẩy phết" vào công thức:
=IFERROR(OFFSET($R$2,MATCH(SUM(B4:O4),{12,18,24},),COUNT(J4:O4)>0),$S$5)

Thân

 

[bebo021999]

Dòng 3 có vùng đầu tiên =1, vùng thứ 2 =11, rơi vào "Khác" đúng không? Sao chủ thớt lại cho KQ mong muốn là S3 thay vì S5 nhỉ? Làm các bác sai theo.

 

[Phan Thế Hiệp]

Dòng 3 có vùng đầu tiên =1, vùng thứ 2 =11, rơi vào "Khác" đúng không? Sao chủ thớt lại cho KQ mong muốn là S3 thay vì S5 nhỉ? Làm các bác sai theo.

Không sai đâu! nó rơi vào điều kiện thứ 3:

"Nếu giá trị từ B4 đến O4 nằm trong khoảng từ B3 đến O3 và tổng =12 thì =S3"

Anh @Ba Tê nghiên cứu kỹ và rất nhạy về điều kiện này, nên khen ảnh hết lời.

Thân

 

[bebo021999]

Không sai đâu! nó rơi vào điều kiện thứ 3:
"Nếu giá trị từ B4 đến O4 nằm trong khoảng từ B3 đến O3 và tổng =12 thì =S3"

Nếu thế thì đơn giản mà, không cần dùng đến OFFSET ( là volatile formula nên ảnh hưởng đến tốc độ tính toán)
Em hiểu thế này có đúng không:
Dùng INDEX tham chiếu vùng R3:S5, với số cột (C) và dòng (R) xác định như sau:
Số dòng:
MATCH(SUM(B4:O4),{12,18,24},0)
Số cột:
1+(SUM(B4:I4)<>SUM(B4:O4))
Nghĩa là trừ khi (tổng vùng 1 = tổng vùng) thì trả về cột R, còn không thì trả về cột S hết

Công thức cuối cùng:

=IFERROR(INDEX($R$3:$S$5,MATCH(SUM(B4:O4),{12,18,24},0),1+(SUM(B4:I4)<>SUM(B4:O4))),$S$5)

 

[Phan Thế Hiệp]

Nếu thế thì đơn giản mà, không cần dùng đến OFFSET ( là volatile formula nên ảnh hưởng đến tốc độ tính toán)
Em hiểu thế này có đúng không:
Dùng INDEX tham chiếu vùng R3:S5, với số cột (C) và dòng (R) xác định như sau:
Số dòng:
MATCH(SUM(B4:O4),{12,18,24},0)
Số cột:
1+(SUM(B4:I4)<>SUM(B4:O4))
Nghĩa là trừ khi (tổng vùng 1 = tổng vùng) thì trả về cột R, còn không thì trả về cột S hết

Công thức cuối cùng:

=IFERROR(INDEX($R$3:$S$5,MATCH(SUM(B4:O4),{12,18,24},0),1+(SUM(B4:I4)<>SUM(B4:O4))),$S$5)

Dùng Count() hay Sum() để tính cột là R hay S, sao cũng được.
=IFERROR(INDEX($R$3:$S$5,MATCH(SUM(B4:O4),{12,18,24},),1+(COUNT(J4:O4)>0)),$S$5)

Còn INDEX() hay OFFSET() thì tùy mỗi người.
Tôi chả quan tâm lắm cái chuyện "vô lây tai", "vai lây tô", hay "vô lai tây" gì sất, lúc làm ngẫu hứng, tôi nghĩ đến hàm nào thì tôi lôi đầu nó ra mà tôi xài thôi.

Thân.

 

[HieuCD]

Em xin chào cả nhà ạ !
Em xin nhờ cả nhà viết giúp em hàm IF với điều kiện trong khoảng, chi tiết em đã ghi chú trong file đính kèm ạ.
Rất mong nhận được sự giúp đỡ của cả nhà ạ.
Em xin chân thành cảm ơn !

Góp vui cách khác với điều kiện tổng cột B tới cột O chỉ có 3 giá trị 12,18,24

P4 =INDEX($R$3:$S$5,SUM(B4:O4)/6-1,1+(SUM(J4:O4)>0))

Hoặc

P4 ="44*"&38+2*(SUM(J4:O4)>0)&"*"&SUM(B4:O4)/6*10