Tính lịch giao hàng dự kiến (1 người xem)

[nguyentebby]

Hi các anh/chị/em,
Nhờ các anh/chị/em giúp đỡ em phần này ạ, em có 1 file như bên dưới. Lịch đặt hàng và giao hàng của mỗi cửa hàng là cố định. Tuy nhiên khi đặt hàng không theo lịch thì phải giao hàng vào lịch kế tiếp.
Em ví dụ: Lịch đặt hàng nhà Nguyễn Văn A là thứ 2 và thứ 5, giao hàng thứ 3 và thứ 6. Nhưng họ đặt vào thứ 3, thì lịch giao hàng là thứ 6, đặt hàng thứ 6, thì lịch giao hàng của họ phải là thứ 3 tuần kế tiếp. Mọi người chỉ em cách tính ngày giao hàng với ạ.
Em cảm ơn nhiều nhiều!!!

 

[dazkangel]

Thử:

=LOOKUP(L3,{1,3;3,6;6,10})-L3+K3

 

[nguyentebby]

Thử:

=LOOKUP(L3,{1,3;3,6;6,10})-L3+K3

kết quả không đúng ạ ((

 

[anhvuong2323]

Dạng nầy theo mình, Bạn dùng lệnh If() kết hợp với Index() để tạo ra 1 bảng "tra" ngày giao theo list ngày đặt và Mã CH có thể kéo dài đến năm vô hạn., rồi bạn dùng index(match(),match()) tìm là dc!
Chúc Bạn thành công!

 

[Hoàng Tuấn 868]

Dạng nầy theo mình, Bạn dùng lệnh If() kết hợp với Index() để tạo ra 1 bảng "tra" ngày giao theo list ngày đặt và Mã CH có thể kéo dài đến năm vô hạn., rồi bạn dùng index(match(),match()) tìm là dc!
Chúc Bạn thành công!

Bạn biết cặn kẽ vậy thì giúp hộ luôn vào file cho mình học hỏi với.

 

[dazkangel]

kết quả không đúng ạ ((

Thử lại thế này xem:

=WORKDAY.INTL(K3,1,TEXT(MMULT(10^{5,4,3,2,1,0},COUNTIF(INDEX(D$3:D$12,MATCH(I3,A$3:A$12,0)),"<>*"&ROW($2:$7)&"*")),"0000001"))

 

[Phuocam]

Nếu Excel 2019 hoặc 365, có thể thử:

'=WORKDAY.INTL(K3,1,textjoin("",1,COUNTIF(INDEX($D$3:$D$12,MATCH(I3,$A$3:$A$12,0)),"<>*"&{2,3,4,5,6,7,"C"}&"*")))

.

 

[dazkangel]

Một cách khác:

=WORKDAY.INTL(K3,1,TEXT(DEC2BIN(127-SUM(IFERROR(2^(8-MID(LOOKUP(I3,A$3:D$12),{5,13,21},1)),))),"0000000"))

 

[nguyentebby]

Một cách khác:

=WORKDAY.INTL(K3,1,TEXT(DEC2BIN(127-SUM(IFERROR(2^(8-MID(LOOKUP(I3,A$3:D$12),{5,13,21},1)),))),"0000000"))

dạ cảm ơn anh ạ, 2 cách đều ra kết quả đúng ạ

Bài đã được tự động gộp: 26/7/21

dạ cảm ơn anh a

Nếu Excel 2019 hoặc 365, có thể thử:

'=WORKDAY.INTL(K3,1,textjoin("",1,COUNTIF(INDEX($D$3:$D$12,MATCH(I3,$A$3:$A$12,0)),"<>*"&{2,3,4,5,6,7,"C"}&"*")))

.

dạ cảm ơn anh ạ