Hỏi: Lọc dữ liệu có các ký tự ấn định trong text (1 người xem)

[ducleminh]

Nhờ các bạn hướng dẫn giùm mình nha
Mình có cột A chứa các ô có text (bao gồm chữ và số), mình muốn dùng hàm làm sao để ở cột B cho kết quả "wrong" nếu cột tẽxt ở cột A có số (hoặc ký tự ấn định) và "true" nếu không có số (hoặc ko có ký tự ấn định)

 

[ndu96081631]

Nhờ các bạn hướng dẫn giùm mình nha
Mình có cột A chứa các ô có text (bao gồm chữ và số), mình muốn dùng hàm làm sao để ở cột B cho kết quả "wrong" nếu cột tẽxt ở cột A có số (hoặc ký tự ấn định) và "true" nếu không có số (hoặc ko có ký tự ấn định)

Gõ công thức này vào cell B2

=IF(SUMPRODUCT(COUNTIF(A2,"*"&(ROW($1:$10)-1)&"*")),"Wrong","True")

Kéo fill xuống
Còn việc đếm xem có bao nhiêu cell có chứa ký tự C thì dùng công thức này:

=COUNTIF($A$2:$A$35,"*C*")

 

[ducleminh]

=IF(SUMPRODUCT(COUNTIF(A2,"*"&(ROW($1:$10)-1)&"*")),"Wrong","True")

Cám ơn bạn nhiều lắm, bạn có thể giải thích giùm mình hàm trên không

 

[ndu96081631]

=IF(SUMPRODUCT(COUNTIF(A2,"*"&(ROW($1:$10)-1)&"*")),"Wrong","True")

Cám ơn bạn nhiều lắm, bạn có thể giải thích giùm mình hàm trên không

ROW($1:$10)-1 tạo ra 1 mảng từ 0 đến 9
COUNTIF(A2,"*"&(ROW($1:$10)-1)&"*") là xem trong cell A2 có số nào là 0, 1, ... hoặc 9 hay không
SUMPRODUCT(COUNTIF(A2,"*"&(ROW($1:$10)-1)&"*")) là cộng lại toàn bộ giá trị mà COUNTIF đã tính
Nếu tìm thấy có số từ 0 đến 9 thì hàm SUMPRODUCT trên sẽ trả về giá trị khác 0 ---> Từ đó mà IF thôi
Lưu ý: Nếu không thích SUMPRODUCT thì có thể thay nó bằng hàm OR ---> Có điều sau khi gõ xong công thức ta phải Ctrl + Shift + Enter (vì là công thức mảng)

=IF(OR(COUNTIF(A2,"*"&(ROW($1:$10)-1)&"*")),"Wrong","True")

 

[tam8678]

ROW($1:$10)-1 tạo ra 1 mảng từ 0 đến 9
COUNTIF(A2,"*"&(ROW($1:$10)-1)&"*") là xem trong cell A2 có số nào là 0, 1, ... hoặc 9 hay không

---
Nhưng anh làm riêng lẽ như thế này không biết có đúng không?
=COUNTIF(A5"*"&(ROW($1:$10)-1)&"*") => kết quả cũng =0, ( A5=1CAAA)
Cám ơn.

 

[ndu96081631]

---
Nhưng anh làm riêng lẽ như thế này không biết có đúng không?
=COUNTIF(A5"*"&(ROW($1:$10)-1)&"*") => kết quả cũng =0, ( A5=1CAAA)
Cám ơn.

Anh dùng chuột bôi đen công thức trên thanh Formula rồi bấm F9 xem, nó sẽ cho kết quả thế này:
={0;1;0;0;0;0;0;0;0;0}
Ý nghĩa:
Số 0: Không tìm thấy
Số 1: Có
Số 2: Không tìm thấy
...
Số 9: Không tìm thấy
Nó là mảng đấy, vì thế nếu muốn nó thể hiện ra kết quả, anh cần phải thêm 1 hàm gì đó để xử lý