HÀM GOM CÁC ĐK LẠI CHO GỌN NHẸ CÔNG THỨC ? (1 người xem)

[dunghtgiga]

Mình có ví dụ (file đính kèm) mình nhờ các bạn hướng dẫn giúp Hàm nào gom các điều kiện lại cho gọn nhẹ công thức ?

 

[Phuocam]

Mình có ví dụ (file đính kèm) mình nhờ các bạn hướng dẫn giúp Hàm nào gom các điều kiện lại cho gọn nhẹ công thức ?

Thử:

=IF(OR(A2={"MH01","MH03","MH06","MH10"}),"VIP 1",IF(OR(A2={"MH02","MH04","MH13","MH09","MH16","MH20"}),"VIP 2","VIP 3"))

 

[VetMini]

Có nguyên cái bảng như vậy thì lý do gì không dùng VLookup?
Nếu không có bảng dùng hàm search string, chia cho vị trí rồi dùng hàm choose.
Đại kháI:
=CHOOSE( Quotient(Search("," & A2 & ", ",MH01,MH03,MH06,MH10,MH02...,"), 4)+1, "VIP 1", "VIP 2", "VIP 3")
hoặc là:
= "VIP " & search cái gì đó

 

[hunglam123]

Có nguyên cái bảng như vậy thì lý do gì không dùng VLookup?
Nếu không có bảng dùng hàm search string, chia cho vị trí rồi dùng hàm choose.
Đại kháI:
=CHOOSE( Quotient(Search("," & A2 & ", ",MH01,MH03,MH06,MH10,MH02...,"), 4)+1, "VIP 1", "VIP 2", "VIP 3")
hoặc là:
= "VIP " & search cái gì đó

Nói như muối bỏ biển.
Ta cần làm 1 bảng dò sau đó cùng Countif cha ơi là cha

=IF(COUNTIF($E$1:$E$10,A1)>0,"vip 1",IF(COUNTIF($F$1:$F$10,A1)>0,"vip 2,","vip 3"))

 

[VetMini]

="VIP " & Match(IfError(Find(","&A2&",", ",MH01,MH03,MH06,MH10,MH02,MH04,MH09,MH13,MH16,MH20,"),9999), { 1, 21, 999 }, 1)

Nếu mã luôn luôn là MHxx thì:
="VIP " & Match(Match(--Right(A2,2), { 1, 3, 6, 10, 2, 4, 9, 13 , 16, 20, 5, 7, 8, 11, 12, 14, 15, 17, 18, 19 }, 0), { 1, 5, 11 }, 1)

 

[HieuCD]

Mình có ví dụ (file đính kèm) mình nhờ các bạn hướng dẫn giúp Hàm nào gom các điều kiện lại cho gọn nhẹ công thức ?

View attachment 238620

="VIP "&IFERROR(MATCH("*" &RIGHT(A2,2)&"*",{"01,03,06,10","02,04,13,09,16,20"},0),3)

 

[VetMini]

="VIP "&IFERROR(MATCH("*" &RIGHT(A2,2)&"*",{"01,03,06,10","02,04,13,09,16,20"},0),3)

Đúng là mình lú lẫn, quên mất rằng khi tìm nhóm thì Match với wildcards đơn giản hơn Find và định vị.

 

[HieuCD]

Đúng là mình lú lẫn, quên mất rằng khi tìm nhóm thì Match với wildcards đơn giản hơn Find và định vị.

Bạn nói quá rồi, chỉ là "Bệnh nghề nghiệp", bạn nhìn vấn đề dưới con mắt của chuyên gia lập trình xử lý dữ liệu, bài toán nầy chỉ là tiểu xảo xử lý tình huống nhỏ, trường hợp khác có thể không dùng được