Công thức đếm ký tự trong một ô!? (1 người xem)

[sieunhi10079]

Cho em hỏi có công thức nào đếm có bao nhiêu ký tự trong một ô không? Công thức đó như thế nào vậy? Mong các anh chị giúp đỡ!

 

[salam]

Đếm ký tự trong một ô bạn dùng hàm.
=len(ô)

 

[dongdv]

Bạn dùng công thức này thử xem. Không biết có đúng ý bạn không!
=LEN(SUBSTITUTE(A1," ",""))

 

[salam]

Bạn dùng công thức này thử xem. Không biết có đúng ý bạn không!
=LEN(SUBSTITUTE(A1," ",""))

Dấu cách cũng là một ký tự đó bạn.

 

[sieunhi10079]

Công thức : =substitute(A1," "," ") là dùng để thay thế ký tự trong dấu ngoặc kép đầu tiên bằng ký tự trong dấu ngoặc kép thứ 2. Còn thêm len(substitute(...)) vào nữa thì mình không rõ là để làm gì!? Có ai biết xin chỉ thêm!

 

[TKT]

Công thức : =substitute(A1," "," ") là dùng để thay thế ký tự trong dấu ngoặc kép đầu tiên bằng ký tự trong dấu ngoặc kép thứ 2. Còn thêm len(substitute(...)) vào nữa thì mình không rõ là để làm gì!? Có ai biết xin chỉ thêm!

Substitute sẽ bỏ khoảng trắng trong chuỗi ví dụ
456 789 10 sẽ thành 45678910 sau đó là Len(45678910)

 

[BNTT]

Công thức này: LEN(A1) là đếm tất cả các ký tự trong ô, kể cả ký tự rỗng (các khoảng trắng).
Ví dụ: Giả sử A1 = Giai Phap Excel, thì LEN(A1) = 15

Công thức : =substitute(A1," "," ") là dùng để thay thế ký tự trong dấu ngoặc kép đầu tiên bằng ký tự trong dấu ngoặc kép thứ 2. Còn thêm len(substitute(...)) vào nữa thì mình không rõ là để làm gì!? Có ai biết xin chỉ thêm!

Còn công thức này: LEN(SUBSTITUTE(A1, " ", ""))
Bạn xem cho kỹ nha, cái nháy nháy phía trước có khoảng trắng ở giữa, còn cái nháy nháy phía sau thì dính liền. Ở cái trích dẫn ở trên, công thức đã bị gõ sai rồi.

Công thức này dùng để đếm các ký tự trong ô, nhưng không đếm các ký tự rỗng, vì hàm SUBSTITUTE(A1, " ", "") đã xóa hết các khoảng trắng rồi.
Do đó, vẫn giả sử A1 = Giai Phap Excel, thì LEN(SUBSTITUTE(A1, " ", "")) = 13

 

[cadafi]

Công thức : =substitute(A1," "," ") là dùng để thay thế ký tự trong dấu ngoặc kép đầu tiên bằng ký tự trong dấu ngoặc kép thứ 2. Còn thêm len(substitute(...)) vào nữa thì mình không rõ là để làm gì!? Có ai biết xin chỉ thêm!

Ví dụ: ta có chuỗi sau: "Sieu Nhi 10079"
Bạn muốn đếm có bao nhiêu ký tự (theo mình hiểu là bạn sẽ không đếm ký tự rỗng!??) thì:
Substitute("Sieu Nhi 10079"," ","") sẽ cho ra "SieuNhi10079"
Vậy Len(Substitute("Sieu Nhi 10079"," ",""))= len("SieuNhi10079") = 12 ký tự.

Vậy nhé bạn. Thân.

 

[id_unique]

Câu hỏi của bạn: Cho em hỏi có công thức nào đếm có bao nhiêu ký tự trong một ô không?
Tôi chưa hiểu rõ ý bạn hỏi lắm, không biết ý bạn là hỏi có bao nhiêu chữ (từ) trong ô hay là ký tự.
Ví dụ: Ô A1 có nội dung là: " Nguyen Van A 1"
- Nếu có bao nhiêu ký tự trong ô A1 thì số ký tự trong ô A1 chính là chiều dài của ô A1: Len(A1) --- khoảng trắng cũng là ký tự.
- Nếu có bao nhiêu chữ (từ) trong ô A1 thì ô A1 có 4 chữ (từ) : "Nguyen" "Van" "A" "1"
công thức để tìm là =IF(LEN(A1)=0,0,LEN(TRIM(A1))-LEN(SUBSTITUTE(TRIM(A1)," ",""))+1)

Hy vọng đúng ý bạn !

 

[sieunhi10079]

Mình đã thực hiện được rồi! Đúng ý và học được thêm nữa, ngoài ý muốn luôn! cảm ơn tất cả mọi người!

Gởi anh BNTT: anh viết sai chỗ công thức SUBSTITUDE đúng là: SUBSTITUTE.
Thân!
(Cảm ơn nhiều. Tạ lỗi bằng cái này)

 

[lethanhtung08]

Chào các bạn !

Cho mình hỏi thêm tý nữa : vd ô A1 có công thức : =11 + 12 + 13, vậy có hàm nào cho kết quả là : có 02 dấu + hoặc : có 03 số.

Cảm ơn các bạn !

L.T.Tùng

 

[MinhCong]

Chào các bạn !

Cho mình hỏi thêm tý nữa : vd ô A1 có công thức : =11 + 12 + 13, vậy có hàm nào cho kết quả là : có 02 dấu + hoặc : có 03 số.

Cảm ơn các bạn !

L.T.Tùng

1/Đếm có bao nhiêu dấu + Bạn dùng công thức len như trên và biến đổi thôi.

 B1=LEN(B1)-LEN(SUBSTITUTE(B1;"[COLOR=Red]+[/COLOR]";"")

2/Còn đếm có bao nhiêu số:

 B1=[B]LEN(B1)-LEN(SUBSTITUTE(B1;"[COLOR=Red]+[/COLOR]";"")+1 [/B]

 

[ndu96081631]

1/Đếm có bao nhiêu dấu + Bạn dùng công thức len như trên và biến đổi thôi.

 B1=LEN(B1)-LEN(SUBSTITUTE(B1;"[COLOR=Red]+[/COLOR]";"")

2/Còn đếm có bao nhiêu số:

 B1=[B]LEN(B1)-LEN(SUBSTITUTE(B1;"[COLOR=Red]+[/COLOR]";"")+1 [/B]

Đếm dấu + thì đúng rồi (chỉ thiếu dấu ngoặc), còn đếm số thì chưa chính xác
Ví dụ Cell A1 chứa chuổi '=11 + 12 - 13

 

[MinhCong]

Đếm dấu + thì đúng rồi (chỉ thiếu dấu ngoặc), còn đếm số thì chưa chính xác
Ví dụ Cell A1 chứa chuổi '=11 + 12 - 13

Nếu vậy Em sửa lại công thức đếm số như thế này:

 LEN(A1)-LEN(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(A1;"+";"");"-";"");"*";"");"/";"");"=";""))+1

 

[Ba Tê]

Chào các bạn !

Cho mình hỏi thêm tý nữa : vd ô A1 có công thức : =11 + 12 + 13, vậy có hàm nào cho kết quả là : có 02 dấu + hoặc : có 03 số.

Cảm ơn các bạn !

L.T.Tùng

Nếu Ô A1 chứa công thức =11+12+13 thì sau khi Enter sẽ nhận kết quả là 36, làm sao có thể tìm được bao nhiêu dấu cộng... trừ phi A1 chứa text mà không phải là công thức.
Vd: '=11+12+13

 

[ndu96081631]

Nếu Ô A1 chứa công thức =11+12+13 thì sau khi Enter sẽ nhận kết quả là 36, làm sao có thể tìm được bao nhiêu dấu cộng... trừ phi A1 chứa text mà không phải là công thức.
Vd: '=11+12+13

Dù là công thức hay text thì vẫn đếm được dấu +
Nói chung vấn đề không phải nằm ở chổ đó ----> Vấn đề là dựa vào đâu để biết rằng ĐÂY LÀ 1 SỐ (số 11 là 1 số, số 12 là 1 số và số 13 là 1 số, vị chi có 3 số)

 

[Ba Tê]

Dù là công thức hay text thì vẫn đếm được dấu +
Nói chung vấn đề không phải nằm ở chổ đó ----> Vấn đề là dựa vào đâu để biết rằng ĐÂY LÀ 1 SỐ (số 11 là 1 số, số 12 là 1 số và số 13 là 1 số, vị chi có 3 số)

Thật ngạc nhiên! Thú thật tôi chưa hình dung ra cách làm, nếu đơn giản ta qui định 1 số gồm 2 chữ số, trong ô chứa công thức có thể đến 10 dấu cộng thì cách tính như thế nào, nhờ Bạn hướng dẫn dùm. Rất mong được thêm hiểu biết.
Thân mến.

 

[ndu96081631]

Thật ngạc nhiên! Thú thật tôi chưa hình dung ra cách làm, nếu đơn giản ta qui định 1 số gồm 2 chữ số, trong ô chứa công thức có thể đến 10 dấu cộng thì cách tính như thế nào, nhờ Bạn hướng dẫn dùm. Rất mong được thêm hiểu biết.
Thân mến.

Ý mình nói là có thể đếm dấu + dù đó là dạng TEXT hay công thức
Dùng hàm Macro 4 để lấy công thức ---> Cái này đã từng nói nhiều trên diển đàn rồi ---> Giống bài này:
http://www.giaiphapexcel.com/forum/showthread.php?t=16824
Ra kết quả chuổi công thức, ta sẽ tiến hành đếm dấu + (giống như bạn MinhCong đã làm)
Còn đếm số thật tình tôi không nghĩ ra

 

[lethanhtung08]

Cảm ơn các bạn !
Tuy nhiên mình vẫn chưa tính được, có lẽ mình chưa hiểu bản chất của công thức này, các bạn giúp mình nhé B1=LEN(B1)-LEN(SUBSTITUTE(B1;"+";"")), mình chưa hiểu những điểm sau đây :
1/ Ô chứa dữ liệu tính toán của mình là A1, tại sao trong công thức trên không có.
2/ Tại sao ô B1 lại bằng chính Len(B1), điều này có nghĩa gì ??

 

[thanhxt2009]

Cảm ơn các bạn !
Tuy nhiên mình vẫn chưa tính được, có lẽ mình chưa hiểu bản chất của công thức này, các bạn giúp mình nhé B1=LEN(B1)-LEN(SUBSTITUTE(B1;"+";"")), mình chưa hiểu những điểm sau đây :
1/ Ô chứa dữ liệu tính toán của mình là A1, tại sao trong công thức trên không có.
2/ Tại sao ô B1 lại bằng chính Len(B1), điều này có nghĩa gì ??

Bạn thử thay B1 bằng A1 xem sao?

 

[lethanhtung08]

Mình đã thử rồi bạn ạ, kết quả = 0, đủng ra phải bằng 2.

 

[Ba Tê]

Mình đã thử rồi bạn ạ, kết quả = 0, đủng ra phải bằng 2.

Bạn xem kỹ lại các bài trao đổi bên trên, nhất là bài #18 của ndu:

Ý mình nói là có thể đếm dấu + dù đó là dạng TEXT hay công thức
Dùng hàm Macro 4 để lấy công thức ---> Cái này đã từng nói nhiều trên diển đàn rồi ---> Giống bài này:
http://www.giaiphapexcel.com/forum/s...ad.php?t=16824
Ra kết quả chuổi công thức, ta sẽ tiến hành đếm dấu + (giống như bạn MinhCong đã làm)
Còn đếm số thật tình tôi không nghĩ ra

 

[lethanhtung08]

Mình vẫn chưa làm được, bạn có thể post mẫu lên giúp mình được không ?

 

[Ba Tê]

Mình vẫn chưa làm được, bạn có thể post mẫu lên giúp mình được không ?

Trời ạ!
Nếu ô A1 của bạn là công thức A1 = 11+12+13.. thì ...?!

Ý mình nói là có thể đếm dấu + dù đó là dạng TEXT hay công thức
Dùng hàm Macro 4 để lấy công thức ---> Cái này đã từng nói nhiều trên diển đàn rồi ---> Giống bài này:
[URL="http://www.giaiphapexcel.com/forum/showthread.php?t=16824"]http://www.giaiphapexcel.com/forum/s...ad.php?t=16824[/URL]
Ra kết quả chuổi công thức, ta sẽ tiến hành đếm dấu + (giống như bạn [COLOR=blue][B]MinhCong[/B][/COLOR] đã làm)
Còn đếm số thật tình tôi không nghĩ ra

Còn nếu ô A1 của Bạn là 1 chuỗi text '=11 + 12 + 13, nghĩa là, sau khi nhập công thức xong Bạn vẫn thấy ô A1 hiện ra giá trị là =11 + 12 + 13 thì Bạn áp dụng công thức của MingCong.
Hy vọng Bạn hiểu được.
- Tôi thì vẫn chưa hiểu Bạn chưa hiểu gì những gì tôi đã hiểu?!?!

 

[ndu96081631]

Mình vẫn chưa làm được, bạn có thể post mẫu lên giúp mình được không ?

Thay vì chờ mọi người post bài mẩu (mà thật ra cũng đã có cả rồi) tôi nghĩ bạn nên đưa file của bạn lên, nói rõ yêu cầu và ghi kết quả mà bạn mong muốn đạt được ---> Thế có phải tốt hơn không?

 

[phong lan hoàng thảo]

Cho em hỏi, vậy muốn đếm số từ (ko phải ký tự) trong 1 ô thì làm thế nào ?

Em gửi file đính kèm, kính nhờ mọi người hướng dẫn.

Xin Cảm ơn trước!

 

[ndu96081631]

Cho em hỏi, vậy muốn đếm số từ (ko phải ký tự) trong 1 ô thì làm thế nào ?

Em gửi file đính kèm, kính nhờ mọi người hướng dẫn.

Xin Cảm ơn trước!

Tại cell Q4 bạn gõ công thức này:

=SUMPRODUCT(IF($B$4:$P$4="",0,LEN($B$4:$P$4)-LEN(SUBSTITUTE($B$4:$P$4,"/",""))+1))

Bấm tổ hợp phím Ctrl + Shift + Enter sau khi gõ xong công thức nhé

 

[salam]

Cho em hỏi, vậy muốn đếm số từ (ko phải ký tự) trong 1 ô thì làm thế nào ?

Em gửi file đính kèm, kính nhờ mọi người hướng dẫn.

Xin Cảm ơn trước!

Bạn dùng ct dưới xem sao.

=SUMPRODUCT(LEN(B4:P4)-LEN(SUBSTITUTE(B4:P4;"/";"")))+COUNTA(B4:P4)

 

[ndu96081631]

Bạn dùng ct dưới xem sao.

=SUMPRODUCT(LEN(B4:P4)-LEN(SUBSTITUTE(B4:P4;"/";"")))+COUNTA(B4:P4)

Công thức rất gọn và hay ---> Có điều chỉ đúng khi vùng tham chiếu là dử liệu thô ---> Nếu có công thức trả về giá trị rổng thì sẽ sai
Vậy liệu có nên sửa thành:

=SUMPRODUCT(LEN(B4:P4)-LEN(SUBSTITUTE(B4:P4,"/","")))+COUNTIF(B4:P4,"><")

???

 

[salam]

Công thức rất gọn và hay ---> Có điều chỉ đúng khi vùng tham chiếu là dử liệu thô ---> Nếu có công thức trả về giá trị rổng thì sẽ sai
Vậy liệu có nên sửa thành:

=SUMPRODUCT(LEN(B4:P4)-LEN(SUBSTITUTE(B4:P4,"/","")))+COUNTIF(B4:P4,"><")

???

Hì hì em xơi theo dư diệu mẫu mà còn trường hợp khác hì hì phải xơi theo kiểu khác vậy.

 

[phong lan hoàng thảo]

Bạn dùng ct dưới xem sao.

=SUMPRODUCT(LEN(B4:P4)-LEN(SUBSTITUTE(B4:P4;"/";"")))+COUNTA(B4:P4)

Rất cảm ơn 2 bạn ndu và salam, mình đã làm được rồi.

Tuy nhiên, 2 bạn quên là mỗi lớp học 2 buổi/ tuần nên kết quả có được phải chia cho 2 thì mới ra chính xác số lớp của GV .

Anyway, thank you a lot!

 

[vth1100]

nếu mình có một dãy số như sau : 123456789 và mình muốn bỏ đi 3 số cuối trong ô đó thì phải làm thế nào ?!
nhờ các bạn giúp mình với
cụ thể là : 1.009.060 thì chỉ cần lấy 1.009
hoặc 11.890.890 thì chỉ cần lấy 11.890 thôi
cám ơn các bạn trước nha.

 

[dat_butmuc]

nếu mình có một dãy số như sau : 123456789 và mình muốn bỏ đi 3 số cuối trong ô đó thì phải làm thế nào ?!
nhờ các bạn giúp mình với

Cho 123456789 tại ô A1,
Công thức tại B1: =LEFT(A1,LEN(A1)-3)

 

[Hai Lúa Miền Tây]

nếu mình có một dãy số như sau : 123456789 và mình muốn bỏ đi 3 số cuối trong ô đó thì phải làm thế nào ?!
nhờ các bạn giúp mình với

Ví dụ A1=123456789 thì bạn làm như sau:

=LEFT(A1,LEN(A1)-3)

 

[ndu96081631]

nếu mình có một dãy số như sau : 123456789 và mình muốn bỏ đi 3 số cuối trong ô đó thì phải làm thế nào ?!
nhờ các bạn giúp mình với
cụ thể là : 1.009.060 thì chỉ cần lấy 1.009
hoặc 11.890.890 thì chỉ cần lấy 11.890 thôi
cám ơn các bạn trước nha.

Như bạn nói ở trên "nếu mình có một dãy số như sau.... " tức dữ liệu của bạn là SỐ, đúng không?
Vậy thì chia cho 1000 rồi lấy phần nguyên
=INT(A1/1000)

 

[chuvanthom]

giup minh voi!

minh co bai toan muon dem toan bo ki tu" khong phai so" cua mot data lon thi minh phai dung ham gi.. và ngược lại muốn đếm toàn bộ số" không phải kí tự" thì dùng hàm j? giúp mình với nhé! xie xie, ni... Thanks... Cảm ơn nhiều

 

[viehoai]

minh co bai toan muon dem toan bo ki tu" khong phai so" cua mot data lon thi minh phai dung ham gi.. và ngược lại muốn đếm toàn bộ số" không phải kí tự" thì dùng hàm j? giúp mình với nhé! xie xie, ni... Thanks... Cảm ơn nhiều

Bạn nghiên cứu bài này và dùng thêm hàm Len() là được thôi
http://www.giaiphapexcel.com/forum/showthread.php?16983-Tách-số-không-dùng-vòng-lặp

 

[kthelaty]

Cho em hỏi có công thức nào đếm có bao nhiêu ký tự trong một ô không? Công thức đó như thế nào vậy? Mong các anh chị giúp đỡ!

Công thức đếm có bao nhiêu ký tự trong một ô :

SUM(LEN(Ô CẦN ĐẾM))

 

[cadafi]

Công thức đếm có bao nhiêu ký tự trong một ô :

SUM(LEN(Ô CẦN ĐẾM))

Hình như hổng cần hàm SUM trong trường hợp này thì phải

 

[thanhnhandp86]

Cho em hỏi co công thức nào lấy các kí tự trước kí tự trống không? Em xin cảm ơn ạ.

 

[Ba Tê]

Cho em hỏi co công thức nào lấy các kí tự trước kí tự trống không? Em xin cảm ơn ạ.

Đề phòng chuỗi trong A1 không có ký tự trống nào:
=LEFT(A1;FIND(" ";A1&" ")-1)

 

[vanle33]

Các bạn cho mình hỏi tiếp chủ đề này
Ví dụ mình có chuỗi như sau ABC-D/GPE/1259-1997
Mình muốn đếm số ký tự là số sau dấu "/" của chữ GPE, nghĩa là chuối số 1259-1997 thì phải dùng công thức nào?
Đếm tay ra kết quả đúng là 9.

 

[ndu96081631]

Các bạn cho mình hỏi tiếp chủ đề này
Ví dụ mình có chuỗi như sau ABC-D/GPE/1259-1997
Mình muốn đếm số ký tự là số sau dấu "/" của chữ GPE, nghĩa là chuối số 1259-1997 thì phải dùng công thức nào?
Đếm tay ra kết quả đúng là 9.

Cái này tương đương với tách tên chứ gì

=LEN(TRIM(RIGHT(SUBSTITUTE(A1,"/",REPT(" ",255)),255)))

Nếu bỏ hàm LEN thì sẽ tách được chuổi 1259-1997

 

[haiphong08]

như công thức trên của anh, em dùng cái hàm này cũng không sai? vậy thêm cái công thức REPT vào làm gì ạ?
Công thức 1 (CT1)

[B]=LEN(RIGHT(H16,9))[/B]

CT2

[B]=LEN(RIGHT(SUBSTITUTE(H16,"-",""),9))[/B]

Kết quả đều ra 9 ký tự.


Em cảm ơn ạ

 

[Hau151978]

như công thức trên của anh, em dùng cái hàm này cũng không sai? vậy thêm cái công thức REPT vào làm gì ạ?
Công thức 1 (CT1)=LEN(RIGHT(H16,9))
CT2 =LEN(RIGHT(SUBSTITUTE(H16,"-",""),9))
Kết quả đều ra 9 ký tự.


Em cảm ơn ạ

Công thức của bạn là do bạn biết kết quả rồi. Right(h16,9) lấy 9 ký tự bên phải chuỗi trong h16, len(right(h16,9)) sẽ ra kết quả 9 mà không phụ thuộc h16, chỉ cần len(h16)>8. Công thức của bạn giống công thức "=9"

 

[cadafi]

như công thức trên của anh, em dùng cái hàm này cũng không sai? vậy thêm cái công thức REPT vào làm gì ạ?
Công thức 1 (CT1)

[B]=LEN(RIGHT(H16,9))[/B]

.......Kết quả đều ra 9 ký tự.

Bạn thử công thức của bạn với chuỗi này xem kết quả còn đúng với đề bài không nha: "ABC-D/GPE/1259-1997-01234"

 

[thanh48ckcd]

Có ai giúp mình với. Trong ô K9 của mình có các ký tự: 20/4,1/5
Mình muốn đếm có bao nhiêu dấu "/" thì làm thế nào?
Mình đã dùng hàm =LEN(K9)-LEN(SUBSTITUTE(K9;"/";"")) nhưng excel cứ báo lỗi không được

 

[phihndhsp]

Mình đã dùng hàm =LEN(K9)-LEN(SUBSTITUTE(K9;"/";"")) nhưng excel cứ báo lỗi không được

Có thể sai là do dấu “;” bạn thử thay bằng dấu “,” xem sao

 

[comet_1701]

Có ai giúp mình với. Trong ô K9 của mình có các ký tự: 20/4,1/5
Mình muốn đếm có bao nhiêu dấu "/" thì làm thế nào?
Mình đã dùng hàm =LEN(K9)-LEN(SUBSTITUTE(K9;"/";"")) nhưng excel cứ báo lỗi không được

Bạn thay dấu ; thành dấu phẩy(,) thử xem

 

[thanh48ckcd]

Thanks nhé, mình thay dấu ";" thành dấu"," thì được rồi

 

[namnhim]

nhờ các bạn giúp tôi có hàm nào đếm có bao nhiêu dấu ( trong 1 ô không:
VD: 746; 785; 786 = 3

 

[doatmenhhon]

nhờ các bạn giúp tôi có hàm nào đếm có bao nhiêu dấu ( trong 1 ô không:
Vd: 746; 785; 786 = 3

 b1=len(a1)-len(substitute(a1,";",""))

 

[namnhim]

anh ơi muốn + thêm 1 số cuối không có dấu phẩy thì làm thế nào nhỉ? như VD trên của em có 2 dấu ( nhưng kết quả phải là 3

 

[lightd]

anh ơi muốn + thêm 1 số cuối không có dấu phẩy thì làm thế nào nhỉ? như VD trên của em có 2 dấu ( nhưng kết quả phải là 3

thì +1 thui,
=1+len(a1)-len(substitute(a1,";",""))

 

[namnhim]

nếu muốn +1 cho về cuối hàm thì để chỗ nào vì nếu đề ở đầu hàng thì ô không chứa ký tự nó hiểu là 1.

 

[giangleloi]

nếu muốn +1 cho về cuối hàm thì để chỗ nào vì nếu đề ở đầu hàng thì ô không chứa ký tự nó hiểu là 1.

IF(a1="","",1+len(a1)-len(substitute(a1,";","")))

 

[nguyen6571gpex]

Chào cả nhà!
Cho tôi hỏi có công thức nào đếm từng loại kí tự không?
VD: Tên tôi là Nguyễn Nam kết quả đếm được: t=2, e=2, n=4, o=1, i=1, l=1, g=1, u=, y=1, a=1, m=1
Cảm ơn mọi người!

 

[befaint]

Chào cả nhà!
Cho tôi hỏi có công thức nào đếm từng loại kí tự không?
VD: Tên tôi là Nguyễn Nam kết quả đếm được: t=2, e=2, n=4, o=1, i=1, l=1, g=1, u=, y=1, a=1, m=1
Cảm ơn mọi người!

Chào nguyen6571gpex,

Giả sử B2="Tên tôi là Nguyễn Nam".
Tại cell [C2] bạn nhập công thức sau:

=IF(LOWER(MID(SUBSTITUTE($B$2," ",""),ROW(A1),1))="","",LOWER(MID(SUBSTITUTE($B$2," ",""),ROW(A1),1))&"="&LEN($B$2)-LEN(SUBSTITUTE(LOWER($B$2),LOWER(MID(SUBSTITUTE($B$2," ",""),ROW(A1),1)),"")))

Kéo fill xuống bao giờ không hiện gì nữa thì thôi.
Sau đó copy/ paste value cột C sang cột bên cạnh rồi sử dụng chức năng Remove Duplicates để loại các dữ liệu trùng.
p/s: Công thức trên không loại được dấu của ký tự nên ký tự có dấu khác nhau sẽ phân biệt, ví dụ: ê và ễ

 

[miracle777]

Có ai biết cách đếm số từ trong 1 ô không chỉ em với

 

[quocgiacan]

Có ai biết cách đếm số từ trong 1 ô không chỉ em với

Ví dụ: A1="Có ai biết cách đếm số từ trong 1 ô không chỉ em với"
a. Nếu tính cả các khoảng trắng:
B1= LEN(A1) sẽ ra 52

b. Nếu chỉ đếm thuần ký tự, không đếm khoảng trắng:
B1=LEN(SUBSTITUTE(A1," ","")) sẽ ra 39

c. Nếu đếm thuần chỉ từng từ thì gộp 2 cách trên:
B1=LEN(A1)-LEN(SUBSTITUTE(A1," ",""))+1 sẽ ra 14 từ

Chúc bạn ngày vui.

 

[VetMini]

c. Nếu đếm thuần chỉ từng từ thì gộp 2 cách trên:
B1=LEN(A1)-LEN(SUBSTITUTE(A1," ",""))+1 sẽ ra 14 từ

Theo kinh nghiệm "dữ iệu đem lên hỏi ở đây không bao giờ chuẩn" (*) thì bạn phải chuẩn hoá trước.
1. phải trim để loại bớt dấu cách2. phải đề phòng trường hợp ô chả có từ nào.

(*) đương nhiên với dấu cách cứng, char160 thì đành chịu. Các loại phân từ khác cũng chịu thua.

 

[Pham Ngoc Trong]

Công thức này: LEN(A1) là đếm tất cả các ký tự trong ô, kể cả ký tự rỗng (các khoảng trắng).
Ví dụ: Giả sử A1 = Giai Phap Excel, thì LEN(A1) = 15


Còn công thức này: LEN(SUBSTITUTE(A1, " ", ""))
Bạn xem cho kỹ nha, cái nháy nháy phía trước có khoảng trắng ở giữa, còn cái nháy nháy phía sau thì dính liền. Ở cái trích dẫn ở trên, công thức đã bị gõ sai rồi.

Công thức này dùng để đếm các ký tự trong ô, nhưng không đếm các ký tự rỗng, vì hàm SUBSTITUTE(A1, " ", "") đã xóa hết các khoảng trắng rồi.
Do đó, vẫn giả sử A1 = Giai Phap Excel, thì LEN(SUBSTITUTE(A1, " ", "")) = 13

Theo cách dùng em hay dùng thì hàm SUBSTITUTE đếm cả dấu "Enter" vô hình (bằng cách gõ Alt + Enter) chứ không đếm ký tự rỗng "", tất nhiên "khoảng trắng" là 1 ký tự rồi ạ!