Nếu số trùng từ 2 số trở lên, loại bỏ số trùng, chỉ giữ lại 1 số. (1 người xem)

[bebo021999]

Xin tư vấn!
Tại ô A1: 11211, tại ô B1 ra kết quả: 121 (11 là 2 số trùng nhau, chỉ giữ lại 1)
Tương tự: A1=13355563333, B1=13563
Xin chỉ giáo công thức tại B1 ạ.
Xin cảm ơn.

 

[Phuocam]

Nếu Excel của bạn có hỗ trợ hàm TEXTJOIN, có thể thử:

=TEXTJOIN("",TRUE,IF(MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1)=MID(A1,ROW(INDIRECT("2:"&LEN(A1)+1)),1),"",MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1)))

Kết thúc bằng Ctrl+Shift+Enter.

 

[huuthang_bd]

Nếu xài đồ cổ

=SUMPRODUCT(MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1)*(MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1)<>MID(" "&A1,ROW(INDIRECT("1:"&LEN(A1))),1))*10^(MMULT(--(ROW(INDIRECT("1:"&LEN(A1)))<=TRANSPOSE(ROW(INDIRECT("1:"&LEN(A1))))),--(MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1)<>MID(" "&A1,ROW(INDIRECT("1:"&LEN(A1))),1)))-1))

 

[dazkangel]

Mọi người làm vui quá, mình xin góp 1 công thức nhỏ (nhấn Ctrl+Shift+Enter):

=SUM(MID(0&A1,LARGE(ROW(INDIRECT("1:"&LEN(A1)))*(MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1)<>MID(A1,ROW(INDIRECT("2:"&LEN(A1)+1)),1)),ROW(INDIRECT("1:"&LEN(A1))))+1,1)*10^(ROW(INDIRECT("1:"&LEN(A1)))-1))

 

[HieuCD]

Mọi người làm vui quá, mình xin góp 1 công thức nhỏ (nhấn Ctrl+Shift+Enter):

=SUM(MID(0&A1,LARGE(ROW(INDIRECT("1:"&LEN(A1)))*(MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1)<>MID(A1,ROW(INDIRECT("2:"&LEN(A1)+1)),1)),ROW(INDIRECT("1:"&LEN(A1))))+1,1)*10^(ROW(INDIRECT("1:"&LEN(A1)))-1))

Công thức quá tuyệt, Excel giới hạn 15 chữ số thay ROW(INDIRECT("1:"&LEN(A1))) bằng ROW(1:20)

=SUM(MID(0&A1,LARGE(ROW(1:20)*(MID(A1,ROW(1:20),1)<>MID(A1,ROW(2:21),1)),ROW(1:20))+1,1)*10^(ROW(1:20)-1))

 

[bebo021999]

Câu hỏi này từ facebook group của mình, và đã được giải quyết!
Cám ơn tất cả các chiến hữu nhé!

 

[huuthang_bd]

Bên diễn đàn nước ngoài có cách vận dụng NPV hay quá

=NPV(-0.9,IF(MID(A2,21-ROW(1:20),1)<>MID(A2,22-ROW(1:20),1),(MID(A2,21-ROW(1:20),1)&0)%))

 

[bebo021999]

Bên diễn đàn nước ngoài có cách vận dụng NPV hay quá

=NPV(-0.9,IF(MID(A2,21-ROW(1:20),1)<>MID(A2,22-ROW(1:20),1),(MID(A2,21-ROW(1:20),1)&0)%))

Hàm NPV nguyên gốc là hàm tài chính. Tuy nhiên vận dụng nó vào xử lý mảng:
Dùng để nhóm các phần tử với nhau:
VD: Sau khi dùng các hàm trung gian tạo ra mảng: {1,"",2,"",5,""8,"")
=NPV(9,Mảng)
=0.1258

 

[ptm0412]

Câu hỏi này từ facebook group của mình, và đã được giải quyết!
Cám ơn tất cả các chiến hữu nhé!

Hàm 365:
=TEXTJOIN("",1,UNIQUE(MID(A1,SEQUENCE(LEN(A1)),1),,0))

 

[batman1]

Hàm 365:
=TEXTJOIN("",1,UNIQUE(MID(A1,SEQUENCE(LEN(A1)),1),,0))

View attachment 259146

Anh không đọc kỹ đầu bài rồi.

 

[ptm0412]

Anh không đọc kỹ đầu bài rồi.

Thỉnh thoảng cũng mắc tội nhanh nhẩu đoảng anh ạ.