Xin cách để hiển thị ra các tiêu đề tương ứng của nội dung trong bảng, 1 tiêu đề có nhiều nội dung (2 người xem)

[bcttymc]

Như tiêu đề mình xin nhờ mọi người hướng dẫn cách để hiển thị ra các tiêu đề tương ứng của nội dung trong bảng, 1 tiêu đề có nhiều nội dung. Cụ thể như ví dụ bên dưới mình có 1 bảng dữ liệu gồm cột tiêu đề và cột nội dung, mình đã dùng hàm tocol để tổng hợp hết tất cả các nội dung thành 1 cột, và hiện tại mình muốn hiển thị tương ứng cột tiêu đề bên cạnh ( như vậy 1 tiêu đề sẽ xuất hiện nhiều lần và tương ứng với nội dung). mình có dùng ChatGPT nhưng khi đưa ra công thức thì ko áp dụng được: =INDEX($C$2:$E$2,MATCH(TRUE,INDEX($C$3:$E$5=G2,0,0),0))

Nhờ mọi người giúp đỡ

 

[Phan Thế Hiệp]

Dùng ChatGPE, thử: ô I2

=LET(vg,C3:E5,cot,TOCOL(vg,,1),HSTACK(cot,INDEX(C2:E2,MAP(cot,LAMBDA(x,MAX((x=vg)*{1,2,3}))))))

Thân

 

[Hoàng Tuấn 868]

Dùng ChatGPE, thử: ô I2
=LET(vg,C3:E5,cot,TOCOL(vg,,1),HSTACK(cot,INDEX(C2:E2,MAP(cot,LAMBDA(x,MAX((x=vg)*{1,2,3}))))))
Thân

Em định không làm vì chủ bài viết tắt, nhưng thấy anh xuất hiện nên lọ mọ làm thử, kết quả cũng có vẻ giống giống anh ạ.
=OFFSET($B$1,,QUOTIENT(ROW(A1)-1,MATCH(REPT("z",255),$B$1:$B$4)-1))

 

[Phan Thế Hiệp]

Em định không làm vì chủ bài viết tắt, nhưng thấy anh xuất hiện nên lọ mọ làm thử, kết quả cũng có vẻ giống giống anh ạ.
=OFFSET($B$1,,QUOTIENT(ROW(A1)-1,MATCH(REPT("z",255),$B$1:$B$4)-1))

Cứ tập viết công thức đi em.

Ở trên anh viết cho vui mà! Kiểu giống cách trả lời của Chat GPT, còn ở đây anh em mình là ChatGPE.

Nếu như xử lý công thức từng dòng thì dễ rồi em, như mình dùng:

=INDEX($C$2:$E$2,MAX((G2=$C$3:$E$5)*{1,2,3}))

Là được.

Chúc em ngày vui

 

[Phan Thế Hiệp]

=OFFSET($B$1,,QUOTIENT(ROW(A1)-1,MATCH(REPT("z",255),$B$1:$B$4)-1))

Sẵn anh đưa vài gợi ý để em tập suy luận chỉnh dần ngày càng lão luyện nha!

1/ Match( "zzz", B1:B4) là được, vì "zzz" là chuỗi lớn rồi, cũng hiếm khi xuất hiện trong 'nội dung'.
2/ Em đã chọn vùng B1:B4, vậy thay vì dùng Match("z",...)-1, thì em dùng Rows(B1:B4)-1
Cứ như vậy, mỗi lần em viết 1 hàm xong, nhìn lại rồi tự hỏi: còn hàm nào thay thế được nó không, riết rồi quen.

Ngày xửa ngày xưa mấy anh chơi khía nhau qua từng công thức, hễ anh viết kiểu này, thì tôi viết kiểu khác...vui lắm. Cứ như vậy lại học được cái hay của nhau, và thành thói quen viết 1 lúc nhiều cách và sử dụng hàm khác nhau.

Vậy nha em.

 

[Hoàng Tuấn 868]

Sẵn anh đưa vài gợi ý để em tập suy luận chỉnh dần ngày càng lão luyện nha!

1/ Match( "zzz", B1:B4) là được, vì "zzz" là chuỗi lớn rồi, cũng hiếm khi xuất hiện trong 'nội dung'.
2/ Em đã chọn vùng B1:B4, vậy thay vì dùng Match("z",...)-1, thì em dùng Rows(B1:B4)-1
Cứ như vậy, mỗi lần em viết 1 hàm xong, nhìn lại rồi tự hỏi: còn hàm nào thay thế được nó không, riết rồi quen.

Ngày xửa ngày xưa mấy anh chơi khía nhau qua từng công thức, hễ anh viết kiểu này, thì tôi viết kiểu khác...vui lắm. Cứ như vậy lại học được cái hay của nhau, và thành thói quen viết 1 lúc nhiều cách và sử dụng hàm khác nhau.

Vậy nha em.

Dạ anh, em cảm ơn anh nhiều ạ.

 

[mrtungcung]

Như tiêu đề mình xin nhờ mọi người hướng dẫn cách để hiển thị ra các tiêu đề tương ứng của nội dung trong bảng, 1 tiêu đề có nhiều nội dung. Cụ thể như ví dụ bên dưới mình có 1 bảng dữ liệu gồm cột tiêu đề và cột nội dung, mình đã dùng hàm tocol để tổng hợp hết tất cả các nội dung thành 1 cột, và hiện tại mình muốn hiển thị tương ứng cột tiêu đề bên cạnh ( như vậy 1 tiêu đề sẽ xuất hiện nhiều lần và tương ứng với nội dung). mình có dùng ChatGPT nhưng khi đưa ra công thức thì ko áp dụng được: =INDEX($C$2:$E$2,MATCH(TRUE,INDEX($C$3:$E$5=G2,0,0),0))

Nhờ mọi người giúp đỡ

View attachment 308816

Mình cần bạn hỗ trợ viết công thức, ai có thể giúp mình với ạ

 

[Duy Tùng 9x]

Không có file nên bạn xem tạm nhé, làm vội cũng hơi dài.
Office 365

=LET(a,C3:E5,f,LAMBDA(s,TOCOL(IFS(a>0,s),,1)),HSTACK(f(a),f(C2:E2)))

Kéo cho 2 cột: F2:g10

=INDIRECT(TEXT(RIGHT(SMALL(IF($C$3:$E$5>0,ROW($3:$5)/1%+COLUMN($C:$E)*10001-{1;2;3}*{1,1,1}*100*(B$2=$C$2)),ROW(A1)),4),"r0c00"),)